///////////
/* Thugs */
///////////

BEGIN ~WWDEL~     // Make sure thug banter initiates
BEGIN ~WWEFF~
BEGIN ~WWSTEN~

//////////////////////
/* Billy's dialogue */
//////////////////////

BEGIN ~WWBILL~    // wwbill is DV  wwbill is Override

IF ~CombatCounter(0)
	Global("WWBooGone","GLOBAL",0)
	Global("WWRudeSod","LOCALS",0)~ THEN RudeSod
SAY ~You have a big ugly nose! Nyahhh!!~
IF ~~ THEN DO ~SetGlobal("WWRudeSod","LOCALS",1)~ EXIT
END

IF ~CombatCounter(0)
	Global("WWBooGone","GLOBAL",0)
	Global("WWRudeSod","LOCALS",1)~ THEN RudeSod2
SAY ~C'mere and I'll tell you a secret...~
= ~MY MOMMY SAYS THAT YOU'RE STUPID!! And... AND YOU HAVE SMELLY FEET!!~
IF ~~ THEN DO ~SetGlobal("WWRudeSod","LOCALS",0)~ EXIT
END

IF ~IsGabber([PC])
	CombatCounter(0)
	Global("WWBooGone","GLOBAL",1)
	!Global("WWMoveToV","LOCALS",2)
	!See("Minsc")~ THEN Rudesod2ii
SAY ~I'm so rich! I got ONE WHOLE GOLD COIN! Bet you don't! Nyah!!~
IF ~~ THEN EXIT
END

IF ~IsGabber([PC])
	CombatCounter(0)
	Global("WWBooGone","GLOBAL",1)
	!Global("WWMoveToV","LOCALS",2)~ THEN Rudesod2i
SAY ~I didn't do nothing! Nothing at all! Go away!~
IF ~~ THEN EXIT
END


IF ~Global("WWBooGone","GLOBAL",1)          // ie he's run into the tavern
	Global("WWBillySeen","GLOBAL",2)        // and you've left Minsc outside...
	Global("WWMoveToV","LOCALS",0)
	AreaCheck("AR0314")
    IsGabber([PC])
	CombatCounter(0)
	!See("Minsc")~ THEN bratness
SAY ~I'm so rich! I got ONE WHOLE GOLD COIN! Bet you don't! Nyah!!~
IF ~~ THEN EXIT
END

IF ~See("Minsc")
	Global("WWMoveToV","LOCALS",2)~ THEN ComplainToVivick
SAY ~Oh mister! He's being mean to me! The big funny looking one!~
IF ~~ THEN DO ~SetGlobal("WWMoveToV","LOCALS",3)~ EXTERN WWVIVI PickOnKid
END

IF ~IsGabber([PC])
	CombatCounter(0)
	Global("WWBooGone","GLOBAL",0)
	Global("WWMoveToV","LOCALS",3)
	Global("WWBillyScared","LOCALS",0)~ THEN FakeScared
SAY ~Oooh, don't come near me, you meanie!~
= ~Don't let this mean <MANWOMAN> hurt me, mister! (whimper)~
IF ~~ THEN DO ~SetGlobal("WWBillyScared","LOCALS",1)~ EXIT
END

IF ~IsGabber([PC])
	CombatCounter(0)
	Global("WWBooGone","GLOBAL",2)~ THEN Rudesod2ii
SAY ~I see you got your hamster back. Sorry for borrowing him, mister (snicker).~
IF ~~ THEN EXIT
END

IF ~~ Cantmakeme
SAY ~I'm not telling and you can't make me! Nyah!~
= ~Unless- unless you give me- 50- no, 5000, no 50,000 gold! Yeah!!~
++ ~50,000 gold?! To a little punk like you? I'll squash you first!~ + Eek
++ ~You must be out of your mind! I could buy 50,000 hamsters for that money!~ + Eek
++ ~I do not have that amount on me at present. Is there no way to reduce the fee?~ + Eek
END

IF ~~ Eek
SAY ~Well you're not getting that smelly rat back then!~
++ ~Vivick, this is getting us nowhere. You seem to have some control over this child. Make him talk.~ EXTERN WWVIVI ControlKid
++ ~I'll let Minsc at you, kid!~ EXTERN WWVIVI ControlKid
END

IF ~Global("WWBillyScared","GLOBAL",1)~ BillyConfes
SAY ~Don't hurt me! I'll tell you everything! I- I sold that little hamster of yours to a funny man. I think his name was Smethy.~
IF ~~ THEN DO ~SetGlobal("WWBillyScared","GLOBAL",2)~ EXTERN MINSCJ SoldBooToHalfling
END

///////////////////////
/* Vivick's dialogue */
///////////////////////

BEGIN ~WWVIVI~

IF ~~ PickOnKid
SAY ~You there, <MANWOMAN>! You'd betteren' explain why that oaf in your party is picking on this poor childer!~
++ ~You'd better explain why you're guarding petty thieves!~ + ThiefBilly
++ ~Picking on children? We were doing no such thing! This boy stole something... precious to us. Well, precious to Minsc, at any rate.~ + ThiefBilly
++ ~Get out of the way, I have a neck to wring!~ + OuttaTheWay
END

IF ~~ ControlKid
SAY ~Okay okay, everyone calm down. I'll get Billy to tells you where your rat is, if you'll give me good reason to do so.~
+ ~CheckStatGT(Player1,14,CHR)~ + ~Trust me, you don't want Minsc to go beserk on you. It's not pretty, unless you find dismemberment and your bloody death 'pretty'.~ + VivickYells
+ ~CheckStatGT(Player1,14,CHR)~ + ~I need give you no reason. You know it's the right thing to do.~ + VivickHigh
+ ~PartyGoldGT(49)~ + ~50 gold- will that do?~ + 50Gold
+ ~PartyGoldGT(499)~ + ~Here's 500 gold. Now get the child talking.~ + 500Gold
+ ~PartyGoldLT(50)~ + ~I cannot think of a reason at present.~ + NoReason
++ ~See this weapon? Do you want it buried in your head?~ + BuriedHead
END

IF ~~ VivickHigh
SAY ~Hmmm. There's something of the truth in your eyes. Go on, Billy, tell 'em where their squeakalot is. You can find some other rat somewhere to play with.~
IF ~~ THEN EXTERN WWBILL Yapper
END

IF ~~ BuriedHead
SAY ~Ah, you are threatening old Vivick now? It's not a clever thing to do.~
++ ~Perhaps it's not clever, but it will be entertaining. Die, scum!~ + FightVivic
++ ~Sorry. I don't know what came over me. Minsc's headwound must be catching.~ + ControlKid2
END

IF ~~ ControlKid2
SAY ~Sure. Now what were we saying before? Yes... if you'll given me a good reason, I'll get Billy to tells you your Boo's whereabouts.~
+ ~CheckStatGT(Player1,14,CHR)~ + ~Trust me, you don't want Minsc to go beserk on you. It's not pretty, unless you find dismemberment and your bloody death 'pretty'.~ + VivickYells
+ ~CheckStatGT(Player1,14,CHR)~ + ~I need give you no reason. You know it's the right thing to do.~ + VivickHigh
+ ~PartyGoldGT(49)~ + ~50 gold- will that do?~ + 50Gold
+ ~PartyGoldGT(499)~ + ~Here's 500 gold. Now get the child talking.~ + 500Gold
+ ~PartyGoldLT(50)~ + ~I cannot think of a reason at present.~ + NoReason
++ ~See this weapon? Do you want it buried in your head?~ + BuriedHead
END

IF ~~ VivickYells
SAY ~Hmmm. Something tells me that <PRO_HESHE>'s no mere gasbag, Billy, and them muscles on that big 'un are something to contend with. Open your mouth and tell <PRO_HIMHER> unless you want a good wallop.~
IF ~~ THEN EXTERN WWBILL Yapper
END

IF ~~ 500Gold
SAY ~Now that be a good reason! Billy, open your yapper.~
IF ~~ THEN DO ~TakePartyGold(500)~ EXTERN WWBILL Yapper
END

IF ~~ THEN Warning2Heal
SAY ~You're injured? Well heal up quickly, then! I won't have my fellas saying I don't fight fair. Come back when you're ready to go.~
IF ~~ THEN DO ~SetGlobal("WWFightVivickNow","GLOBAL",0)~ EXIT
END

IF ~IsGabber([PC])
	Global("WWFightVivickNow","GLOBAL",0)
	Global("WWFightVivick","GLOBAL",1)		// Minsc fights
	HPPercentLT("Minsc",75)~ THEN Warning2Heal2
SAY ~Look, get your man healed first, then come back and we'll fight, eh?~
+ ~HPPercentGT(Player1,74)
	IsGabber(Player1)~ + ~I would like to stand in for Minsc instead.~ DO ~SG("WWFightVivick",2)~ EXTERN WWVIVI QuickFight
+ ~HPPercentGT(Player1,74)
   !IsGabber(Player1)~ + ~<CHARNAME> will stand in for Minsc instead.~ DO ~SG("WWFightVivick",2)~ EXTERN WWVIVI QuickFight
++ ~Certainly.~ EXIT   // Fight off
END

IF ~IsGabber([PC])
	Global("WWFightVivickNow","GLOBAL",0)
	Global("WWFightVivick","GLOBAL",2)	    // PC fights
	HPPercentLT([PC],75)~ THEN Warning2Heal3
SAY ~Look, get yourself healed first, then come back and we'll fight, eh?~
+ ~HPPercentGT("Minsc",74)~ + ~Minsc will fight instead.~ DO ~SetGlobal("WWFightVivick","GLOBAL",1)~ EXTERN WWVIVI QuickFight
++ ~Certainly.~ EXIT
END

IF ~IsGabber([PC])
	Global("WWFightVivickNow","GLOBAL",0)
	Global("WWFightVivick","GLOBAL",1)		// Minsc fights
	HPPercentGT("Minsc",74)
    PartyGoldLT(50)~ THEN Back2
SAY ~Hmm, no gold on you, eh? Well I likes a good fight anyways. What say you?~
++ ~I say - go for the eyes, Minsc!~ + QuickFight
+ ~HPPercentGT(Player1,74)
	IsGabber(Player1)~ + ~I will stand in for Minsc.~ DO ~SetGlobal("WWFightVivick","GLOBAL",2)~ EXTERN WWVIVI QuickFight
+ ~HPPercentGT(Player1,74)
	!IsGabber(Player1)~ + ~<CHARNAME> will stand in for Minsc.~ DO ~SetGlobal("WWFightVivick","GLOBAL",2)~ EXTERN WWVIVI QuickFight
++ ~Not just yet.~ EXTERN WWVIVI ComeLater
END

IF ~IsGabber([PC])
	Global("WWFightVivickNow","GLOBAL",0)
	Global("WWFightVivick","GLOBAL",2)		// PC Fights
	HPPercentGT(Player1,74)
    PartyGoldLT(50)~ THEN Back3
SAY ~Back for more? And you've got no gold on you, eh? Well I likes a good fight anyways. What say you?~
++ ~Not quite yet.~ EXTERN WWVIVI ComeLater
+ ~HPPercentGT("Minsc",74)~ + ~Minsc will fight instead.~ DO ~SetGlobal("WWFightVivick","GLOBAL",1)~ EXTERN WWVIVI QuickFight
+ ~IsGabber(Player1)~ + ~I am ready.~ EXTERN WWVIVI QuickFight
+ ~!IsGabber(Player1)~ + ~<CHARNAME> is ready.~ EXTERN WWVIVI QuickFight
END

IF ~IsGabber([PC])
	Global("WWFightVivickNow","GLOBAL",0)
	Global("WWFightVivick","GLOBAL",1)		// Minsc fights
	HPPercentGT("Minsc",74)
	PartyGoldGT(49)~ THEN Back2
SAY ~Right, your man looks all healed up. Let's go!~
++ ~Right. Go for the eyes, Minsc!~ + QuickFight
+ ~HPPercentGT(Player1,74)
	IsGabber(Player1)~ + ~I will stand in for Minsc.~ DO ~SetGlobal("WWFightVivick","GLOBAL",2)~ EXTERN WWVIVI QuickFight
+ ~HPPercentGT(Player1,74)
	!IsGabber(Player1)~ + ~<CHARNAME> will stand in for Minsc.~ DO ~SetGlobal("WWFightVivick","GLOBAL",2)~ EXTERN WWVIVI QuickFight
++ ~Not just yet.~ EXTERN WWVIVI ComeLater
END

IF ~IsGabber([PC])
	Global("WWFightVivickNow","GLOBAL",0)
	Global("WWFightVivick","GLOBAL",2)		// PC Fights
	HPPercentGT(Player1,74)
	PartyGoldGT(49)~ THEN Back3
SAY ~So you're ready to fight now? Let's go!~
++ ~Not quite yet.~ EXTERN WWVIVI ComeLater
+ ~HPPercentGT("Minsc",74)~ + ~Minsc will fight instead.~ DO ~SetGlobal("WWFightVivick","GLOBAL",1)~ EXTERN WWVIVI QuickFight
+ ~IsGabber(Player1)~ + ~I am ready.~ EXTERN WWVIVI QuickFight
+ ~!IsGabber(Player1)~ + ~<CHARNAME> is ready.~ EXTERN WWVIVI QuickFight
END

IF ~~ QuickFight
SAY ~Then let's get into it! We'll go over there against the wall, eh? No use hitting anybody else by accident.~
IF ~~ THEN DO ~ ClearAllActions()
				SetGlobal("WWFightVivickNow","GLOBAL",1)
			    SetGlobal("WWSetSlot","GLOBAL",0)~ EXIT
END


IF WEIGHT #-2 ~Global("WWFightVivickNow","GLOBAL",3)
	PartyGoldGT(49)~ THEN VivickWins
SAY ~Ahh, 50 gold, if you please. Pleasure fighting with you, 'specially as it gives me more gold for ale! I'm shouting tonight, boys!~
= ~As for you, comes on back for a rematch once you've healed up.~
IF ~~ THEN DO ~	TakePartyGold(50)
				SetGlobal("WWFightVivickNow","GLOBAL",0)
				ClearAllActions()~ EXIT
END

IF WEIGHT #-1 ~Global("WWFightVivickNow","GLOBAL",3)
	PartyGoldLT(50)~ THEN VivickWins2
SAY ~Ahh well, you've lost but at least you ain't dead. Pleasure fighting with you, 'specially as it makes me look the goods in front of the boys!~
= ~As for you, comes on back for a rematch once you've healed up.~
IF ~~ THEN DO ~SetGlobal("WWFightVivickNow","GLOBAL",0)
			ClearAllActions()~ EXIT
END

///////////////////////
/* Smethy's dialogue */
///////////////////////

BEGIN ~WWSWOO~

IF ~Global("WWYouAttackedMeYouBastards","LOCALS",1)~ HitSmethy
SAY ~You.. you attack old Smethy? But why?!~
= ~Billy brought you in here... it's about that hamster, isn't it?~
= ~Never should have bought the critter from him. Didn't get much gold from him anyway. I suppose you'll be wanting to know where he is? No, don't glare at me like that.~
= ~Look, I sold him to a girl named Eleanya, right? From the Government District. A fancy toff, said she would take the hamster for a swim. Who was I to disagree? That's all I know, I swear!~
= ~I.. I think it's time you left.~
IF ~~ THEN 	UNSOLVED_JOURNAL ~Where oh where has my little Boo gone?

The little boy who stole Boo has led us to the strange store of a halfling by the name of Smethy, or as he revealed to us, Smethyethyldiethylether, the Magnificent. We appear to have arrived just a moment too late and Boo has been sold to a noblewoman called Eleanya. We are to find Eleanya in the Government District where she has been teaching Boo to swim. Something tells me that should not delay too long in this quest...~
			DO ~SetGlobal("WWHelpFindBoo","GLOBAL",6)
			   RealSetGlobalTimer("WWFindBooTimer","GLOBAL",600)  		// ie Minsc's last complaint will run after 10 min of no Boo
			   SetGlobal("WWInspectFountain","GLOBAL",1)
			   ClearAllActions()
			   StartCutSceneMode()
			   StartCutScene("WWgovt")~ EXIT
END

IF ~Global("WWSwooChastens","GLOBAL",1)~ ShameOnYou
SAY ~Well, I don't blame him for leaving. Nasty thing to do to a friend.~
++ ~I seem to recall *you* playing an instrumental part in this.~ DO ~SetGlobal("WWSwooChastens","GLOBAL",2)~ + TrueEnough
++ ~Nasty, eh? Do you want to see how nasty I can get, halfling? See my weapon? It's got your name written on it. In *your* blood.~ DO ~SetGlobal("WWSwooChastens","GLOBAL",2)~  + Hellpp
END

IF ~Global("WWPrettyPenny","LOCALS",0)
    Global("WWSwooTalk2","GLOBAL",3)~ PrettyPenny
SAY ~Ah, but you see, I've already sol-~
++ ~200 gold. Take it or leave it.~ DO ~SetGlobal("WWPrettyPenny","LOCALS",1)~ + TakeIt
++ ~You've already sold him? Oh no!~ DO ~SetGlobal("WWPrettyPenny","LOCALS",1)~ EXTERN MINSCJ YouSoldBoo
END

IF ~Global("WWSwooTakes","LOCALS",0)
    Global("WWSwooTalk2","GLOBAL",3)~ TakeIt
SAY ~200 gold,eh?~
= ~For 200 gold, I believe that Boo is right in this cage over here. I'll just get him out for you, <SIRMAAM>.~
IF ~~ THEN DO ~SetGlobal("WWSwooTakes","LOCALS",1)
			TakePartyGold(200)
			MoveToPoint(\[216.149\])
			MoveToObject("Minsc")
	//		GiveItemCreate("wwnboo","Minsc",0,0,0)
			ActionOverride("Minsc",ReallyForceSpellRES("wwfboo",Myself))
			SetGlobal("WWBooGone","GLOBAL",3)
			ActionOverride("Minsc",ChangeAIScript("wwbant",OVERRIDE))
			SetGlobalTimer("WWFakeBooTimer","GLOBAL",ONE_DAY)
			SG("WWWaitForComment",4)~ EXIT
END

IF ~Global("WWSwooTalk2","GLOBAL",3)~ EllyLivesWhereNasty
SAY ~No need to get nasty on me! Let me think...~
IF ~~ GOTO EllyLivesWhere
END

IF ~Global("WWSwooTalk2","GLOBAL",3)~ EllyLivesWhere
SAY ~Well, 50 gold is alot for a young woman to be carrying. My guess is she comes from those fancy houses in the near Government Park. You should try looking there.~
++ ~Thank you for your help.~ + NoProbs
++ ~Well, we should go to the Government District then. Send us there, will you?~ + NoProbs
++ ~Thanks for the info, midget! Now I'll be squishing you!~ + Hellpp
END

IF ~Global("WWSwooTalk2","GLOBAL",3)~ NoProbs
SAY ~No problem. Good luck finding your hamster, <SIRMAAM>.~
IF ~~ THEN 	UNSOLVED_JOURNAL ~Where oh where has my little Boo gone?

The little boy who stole Boo has led us to the strange store of a curious halfling by the name of Smethy. We appear to have arrived just a moment too late and Boo has been sold to a noblewoman called Eleanya. We are to find Eleanya in the Government District where she has been teaching Boo to swim. Something tells me that should not delay too long in this quest...~
			DO ~SetGlobal("WWHelpFindBoo","GLOBAL",6)
			RealSetGlobalTimer("WWFindBooTimer","GLOBAL",600)  		// ie Minsc's last complaint will run after 10 min of no Boo
			SetGlobal("WWInspectFountain","GLOBAL",1)
			ClearAllActions()
			Wait(1)
			StartCutSceneMode()
		    StartCutScene("WWgovt")~ EXIT
END

IF ~Global("WWSwooTalk2","GLOBAL",3)~ Hellpp
SAY ~You're- you're attacking me? Little old Smethy?! Hel-~
= ~Help me! Oh gods, these animals won't be able to help me! Aieeee!!~
IF ~InParty("Jaheira")~ THEN EXTERN JAHEIRAJ IdiotCharname
IF ~!InParty("Jaheira")~ THEN GOTO niceMan
END

IF ~Global("WWSwooTalk2","GLOBAL",3)~ niceMan
SAY ~I know! I'll just magic you out!! Yes, I am no mild-mannered pet store attendant! I am actually an arch-mage...~
= ~I am Smethyethyldiethylether, the Magnificent! People said I should've been an alchemist, but well- you can't pat a potion, can you?~
= ~Butaneno... hexanona... isopropylenanonn...~
= ~You will not see me again. Goodbye, foolish one- and be glad that I'm setting you free.~
IF ~~ THEN  UNSOLVED_JOURNAL ~Where oh where has my little Boo gone?

The little boy who stole Boo has led us to the strange store of a halfling by the name of Smethy, or as he revealed to us, Smethyethyldiethylether, the Magnificent. We appear to have arrived just a moment too late and Boo has been sold to a noblewoman called Eleanya. We are to find Eleanya in the Government District where she has been teaching Boo to swim. Something tells me that should not delay too long in this quest...~
			DO ~SetGlobal("WWHelpFindBoo","GLOBAL",6)
			   RealSetGlobalTimer("WWFindBooTimer","GLOBAL",600)  		// ie Minsc's last complaint will run after 10 min of no Boo
			   SetGlobal("WWInspectFountain","GLOBAL",1)
			   ClearAllActions()
			   StartCutSceneMode()
			   StartCutScene("WWgovt") ~ EXIT
END

IF ~~ TrueEnough
SAY ~True enough, but blaming me doesn't help you get your friend back, does it? Now, are you going to buy an animal companion or not?~
++ ~Sure, let me have a look at your hares- I mean, wares.~ + BuyStock
++ ~Just let us out of here, would you?~ + Exit
END

IF ~~ BuyStock
SAY ~Hmm, on second thoughts, one who'd betray a friend would likely betray their furry, finned or feathered buddies. I think you should just leave.~
++ ~I'm willing to pay you plenty!~ + PayPlenty
++ ~I'm tired of talking to you. Die, little man! I'll loot your store *after* you're gone.~ + Hellpp
++ ~Just take us to the exit, would you?~ + Exit
END

IF ~~ PayPlenty
SAY ~But *I'm* not willing to let a grubby backstabber like you near my stock. They have *some* dignity you know.~
++ ~I'm tired of talking to you. Die, little man! I'll loot your store *after* you're gone.~ + Hellpp
++ ~Yes yes, save your lectures for somebody who cares for our opinion. Just take us to the exit, would you?~ + Exit
END

IF ~~ Exit
SAY ~Off you go, then. Hope your friend is well rid of you.~
= ~Open... petsmany... (mutter mutter)... dooba!~
IF ~~ THEN  SOLVED_JOURNAL ~Where oh where has my little Boo gone?

A minor error on my part has led to the departure of our great ranger friend Minsc. I attempted to trick him with a false hamster, but he saw through my ruse with astonishing acuity. He has left to find Boo and I can only hope that we shall meet again...~
				DO ~SetGlobal("WWHelpFindBoo","GLOBAL",6)
			   SetGlobal("WWInspectFountain","GLOBAL",1)
			   EraseJournalEntry(@2)
			   EraseJournalEntry(@3)
			   ClearAllActions()
			   StartCutSceneMode()
			   StartCutScene("WWgovt")~ EXIT
END

///////////////////////
//* Elly's Dialogue *//
///////////////////////


BEGIN ~WWELLE~

IF ~!InParty("Minsc") 
    IsGabber([PC])~ THEN BEGIN EllyLooksDown
SAY ~(Snort!) Can I not admire a fountain without being poked by commoners such as yourself? Look at my robe. Soiled! I shall have to find my launderess. Excuse me.~
IF ~~ THEN DO ~EscapeArea()~ EXIT
END

IF ~!Detect("Minsc")
	IsGabber([PC])
	Global("WWFluff","LOCALS",0)~ THEN BEGIN EllyLooksDown2
SAY ~Do NOT touch me, beggar, lest I be forced to bathe!~
IF ~~ THEN EXIT
END

IF ~IsGabber([PC])
	Global("WWFluff","LOCALS",1)~ THEN BEGIN EllyLooksDown2
SAY ~Away with you! These robes must be hand-washed and my launderess has a tendency to get shirty.~
IF ~IsValidForPartyDialog("Minsc")~ THEN EXTERN MINSCJ SeeElly
IF ~~ THEN DO ~SetGlobal("WWFluff","LOCALS",0)~ EXIT
END

IF ~Global("WWFightElle","GLOBAL",3)~ THEN BEGIN EllySnorts
SAY ~And as for you...~
IF ~~ THEN DO ~SetGlobal("WWFightElle","GLOBAL",1)
				Enemy()~ EXIT
END

IF ~Global("WWAfterSpell","LOCALS",2)~ AfterSpell
SAY ~There! Pure harmony in the magical stakes, if I may say so myself.~
++ ~Looks like you hit Minsc with your second last spell.~ + hitMinsc
++ ~Great show. Not.~ + not
+ ~Gender(Player1,MALE) CheckStatGT(Player1,14,CHR)~ + ~My thanks to you, lady De'Lyl. Might a poor <RACE> beg a parting kiss?~ + yuck
+ ~Gender(Player1,FEMALE)~ + ~My thanks to you, lady De'Lyl.~ + nothanksdude
END


IF ~~ not
SAY ~I suppose I was expecting too much in assuming that a commoner would appreciate my artistry. Very well! We shall part in mutual disrespect, unjustified as it may seem.~
++ ~Well, you did hit Minsc with your second last spell.~ + hitMinsc
+ ~Gender(Player1,MALE) CheckStatGT(Player1,14,CHR)~ + ~Apologies and my thanks to you, lady De'Lyl. Might a poor <RACE> beg a parting kiss?~ + yuck
+ ~Gender(Player1,FEMALE)~ + ~Apologies, and my thanks to you, lady De'Lyl.~ + nothanksdude
END

IF ~~ yuck
SAY ~'Poor' is the word for it. You might be intelligent.. and rather charming, but Father would dislike it if I came come crawling with disease.~
IF ~~ THEN GOTO ConsiderThis
END

IF ~~ nothanksdude
SAY ~It was nothing! Merely a small flex of my considerable magic muscle!~
++ ~Although your magic muscle could use some aim... I distinctly saw that you hit Minsc, not Boo, with your spell.~ + hitMinsc
++ ~Whatever you say. You missed Boo with that last spell, by the way.~ + hitMinsc
END

IF ~~ ConsiderThis
SAY ~Consider my 'gift' to your ranger friend a gift enough.~
++ ~A gift to Minsc? What did you do to him?! You were meant to be casting on Boo!~ + hitMinsc
++ ~Hold on. You were casting the spell on Boo, weren't you? What's this about 'gifting' Minsc?~ + hitMinsc
END

IF ~~ Inbred
SAY ~You insult a member of the De'Lyl family? One supremely blessed in magics?~
++ ~You forgot 'supremely blessed in arrogance and idiocy' as well. Hand over the hamster, madam, or you die. Is that simple enough for you?~ + FieOnYou
+ ~CheckStatGT(Player1,13,CHR)~ + ~Calm down. I only want to know what you're doing with the hamster.~ DO ~SetGlobal("WWEleanyaTalk","GLOBAL",1)~ + HamsterSwimHigh
+ ~!CheckStatGT(Player1,13,CHR)~ + ~Calm down lady. What are you doing with the hamster anyway?~  DO ~SetGlobal("WWEleanyaTalk","GLOBAL",1)~ + HamsterSwimLow
++ ~But the hamster is the property of Minsc here.~ DO ~SetGlobal("WWEleanyaProperty","GLOBAL",1)~ + Yours
++ ~I do not want to come to blows, but we will have to fight if you continue to withhold Boo from his rightful owner!~ + NoWay
END

IF ~~ WhatIsThis
SAY ~What-~
= ~What is the meaning of this?! Can I not take my hamster for a swim without having to contend with overdressed adventurers crashing about?~
+ ~CheckStatGT(Player1,13,CHR)~ + ~I'm interested in knowing why you are taking the hamster for a swim.~ DO ~SG("WWEleanyaTalk",1)~ + HamsterSwimHigh
+ ~!CheckStatGT(Player1,13,CHR)~ + ~I need to ask- why are you taking the hamster for a swim?~ DO ~SG("WWEleanyaTalk",1)~ + HamsterSwimLow
++ ~Hand over the hamster, madam, and nobody gets hurt.~ + UnhandHamster
++ ~No you may not. Change your tone quickly or else I'll crash YOU about.~ + ChangeTone
END

IF ~~ ChangeTone
SAY ~And upon whose authority do you threaten me? No, wait, I do not care. Leave at once, else I call in my guards to dispose of you.~
++ ~Looks like we've run into another poncy noble needing a sore kick to the behind. I'll start, Minsc, you can follow.~ + Inbred
++ ~There is no need for you to call in the guards. Just give us the hamster and we'll leave you in peace.~ + UnhandHamster
++ ~Sorry, madam, but you are holding a hamster that rightfully belongs to my friend here. It would be best if you would return it.~ DO ~SetGlobal("WWEleanyaProperty","GLOBAL",1)~ + Yours
+ ~CheckStatGT(Player1,13,CHR)~ + ~Don't be so hasty. I'd like to ask what you're doing with this hamster first.~ DO ~SetGlobal("WWEleanyaTalk","GLOBAL",1)~ + HamsterSwimHigh
+ ~!CheckStatGT(Player1,13,CHR)~ + ~I'd like to ask what you're doing with this hamster first.~ DO ~SetGlobal("WWEleanyaTalk","GLOBAL",1)~ +  HamsterSwimLow
END

IF ~~ Yours
SAY ~This hamster is yours? Hardly likely. I bought him with my own money. I've also invested quite abit of magic in him, so he is more mine than ever before. Aren't you, Pootles?~
+ ~CheckStatGT(Player1,13,CHR)
   !G("WWEleanyaTalk",1)~ + ~You've invested magic in him? What are you doing with him anyway?~ DO ~SG("WWEleanyaTalk",1)~ +  HamsterSwimHigh
+ ~!CheckStatGT(Player1,13,CHR)
   !G("WWEleanyaTalk",1)~ + ~You've invested magic in him? What are you doing with him anyway?~ DO ~SG("WWEleanyaTalk",1)~ +  HamsterSwimLow
+ ~G("WWEleanyaTalk",1)~ + ~I have no time for this verbal sparring. Will you give me the hamster, or will I have to fight you for it? It's your choice.~ + NoWay
++ ~(Pootles?!) Lady, I'm serious, give me the hamster or else I'll kill you.~ + LifeFor
++ ~Right. You named the hamster Pootles. Just for that, you're going to die.~ + LifeFor
END

IF ~~ LifeFor
SAY ~You want to threaten me? A member of the De'Lyl family, supremely blessed in magics?~
++ ~I do not want to come to blows, but we will have to fight if you continue to withhold Boo from his rightful owner!~ + NoWay
++ ~I'll not only threaten you, I'll kill you. Right now, in fact.~ + FieOnYou
+ ~CheckStatGT(Player1,13,CHR)
   !G("WWEleanyaTalk",1)~ + ~Calm down. I only want to know what you're doing with the hamster.~ + HamsterSwimHigh
+ ~!CheckStatGT(Player1,13,CHR)
   !G("WWEleanyaTalk",1)~ + ~Calm down lady. What are you doing with the hamster anyway?~ + HamsterSwimLow
+ ~!G("WWEleanyaProperty",1)~ + ~But the hamster is the property of Minsc here.~ + Yours
END

IF ~~ LifeFor2
SAY ~Threats bore me. Either act on them and face the might of the De'Lyl guardsmen, or get gone from my sight.~
++ ~Then call on your guards now! The more blood the better!~ + FieOnYou
++ ~Then we are at an impasse. I'm not leaving but I do not wish to fight you for Boo.~ + NoWay
END

IF ~~ FieOnYou
SAY ~Fie on you! I'll have to teach you a lesson...~
IF ~~ THEN DO ~ClearAllActions()
			   StartCutSceneMode()
			   StartCutScene("wwctel")~ EXIT
END

// NoWay 1000Gold GreaterThings
IF ~~ 1000Gold
SAY ~You insult the De'Lyls in such a way? We have no want for gold! And the amount you offer is a pittance besides!~
++ ~Is there no way you will return the hamster to us? I do not want to beg you, but I will if need be.~ + NoWay
++ ~I will add injury to my insult in a moment! Give me the hamster.~ + LifeFor2
++ ~I tire of this prattle. Give me the hamster, or your life is forfeit.~ + LifeFor2
END


IF ~~ LoseWhat
SAY ~(Snort!) Don't try to second-guess me, <MANWOMAN>. I'd prefer a battle of wits over a flea-bitten hamster anyday. Yes, even one with my magic in him. I can just buy another one.~
= ~And haven't I told you that I am rather powerful?  It won't take me above an hour to spell up a new hamster.~
++ ~Say, if you're that powerful, how would you like to join with us? I'm hunting a mage named Irenicus...~ + InsultDelyl
++ ~All right. I suppose if it benefits me, I will not question your reasoning. Ask your questions.~ + ToQuestions
++ ~I'm not going to play your idiot games. You obviously don't want to give up the hamster, so we'll just take it off your dead body.~ + FieOnYou
END

IF ~~ NoWay
SAY ~Hmmm... it need not come to that. I see this hamster- Boo, is it? - is of some great importance to your friend... Hmph. Pootles is a much better name. (Sniff!)~
= ~Well, the De'Lyl family is not without its charitable inclinations. I will ask you three questions. If you answer them to my satisfaction, your friend may have his hamster back. If not, then I keep 'Boo' and will hear no more from you.~
= ~Those are my terms. Now do you agree, or do we battle to the death this day?~
++ ~I agree to your terms.~ + ToQuestions
++ ~And what's the catch? What do you want from us if we answer incorrectly?~ + LoseWhat
++ ~I'm not going to play your idiot games. You obviously don't want to give up the hamster, so we'll just take it off your dead body.~ + FieOnYou
END

IF ~~ garnet
SAY ~A red stone... ugh. Not what I would have picked to go with a dark blue dress, but if I must be a pioneer in risqué fashion, so I must.~
= ~Of course, this means I don't have to carry around all these other rocks... they merely weigh me down. I don't suppose you want them?~
= ~You may do with them what you will. Clunky things, most of them.~
IF ~~ THEN DO ~GiveItemCreate("HELM19",Player1,0,0,0)
				GiveItemCreate("AMUL12",Player1,0,0,0)
				GiveItemCreate("MISC36",Player1,0,0,0)
				GiveItemCreate("MISC43",Player1,0,0,0)
				GiveItemCreate("MISC42",Player1,0,0,0)
				GiveItemCreate("MISC41",Player1,0,0,0)~ GOTO Rewards
END

IF ~~ diamond
SAY ~A diamond... (yawn). I suppose you also want me to wear gold pantaloons beneath my dress, as those were also from the last season.~
= ~But if anyone can carry out a retrospective, a De'Lyl can. I will wear a diamond tonight. This of course means that I don't have to carry around all these other rocks... they merely weigh me down. I don't suppose you want them?~
= ~You may do with them what you will. Clunky things, most of them.~
IF ~~ THEN DO ~GiveItemCreate("HELM19",Player1,0,0,0)   // Ioun
				GiveItemCreate("MISC34",Player1,0,0,0)  // Garnet
				GiveItemCreate("MISC36",Player1,0,0,0)  // Pearl
				GiveItemCreate("MISC43",Player1,0,0,0)  // Emerald
				GiveItemCreate("AMUL12",Player1,0,0,0)  // Laeral's tear
				GiveItemCreate("MISC41",Player1,0,0,0) // Sapphire
				~ GOTO Rewards
END

IF ~~ pearl
SAY ~A pearl... why don't you ask me to become a fishwife and shell the oyster as well? Pearls are beneath my standing.~
= ~Although they do create rather a stunning contrast with my skin. And if it means I don't have to carry around all these other rocks... then so be it. I don't suppose you want them?~
= ~You may do with them what you will. Clunky things, most of them.~
IF ~~ THEN DO ~GiveItemCreate("HELM19",Player1,0,0,0)   // Ioun
				GiveItemCreate("MISC34",Player1,0,0,0)  // Garnet
				GiveItemCreate("MISC42",Player1,0,0,0)  // Diamond
				GiveItemCreate("MISC43",Player1,0,0,0)  // Emerald
				GiveItemCreate("AMUL12",Player1,0,0,0)  // Laeral's tear
				GiveItemCreate("MISC41",Player1,0,0,0) // Sapphire
				~ GOTO Rewards
END

IF ~~ ioun
SAY ~An ioun... yes, that will make me look rather fetching. Plus you can never be too sure what mischief the guests are planning by way of enchantment spells and the like. I will wear an ioun tonight.~
= ~Of course, this means I don't have to carry around all these other rocks... they merely weigh me down. I don't suppose you want them?~
= ~You may do with them what you will. Clunky things, most of them.~
IF ~~ THEN DO ~GiveItemCreate("MISC36",Player1,0,0,0)   // Pearl
				GiveItemCreate("MISC34",Player1,0,0,0)  // Garnet
				GiveItemCreate("MISC42",Player1,0,0,0)  // Diamond
				GiveItemCreate("MISC43",Player1,0,0,0)  // Emerald
				GiveItemCreate("AMUL12",Player1,0,0,0)  // Laeral's tear
				GiveItemCreate("MISC41",Player1,0,0,0) // Sapphire
				~ GOTO Rewards
END

IF ~~ emerald
SAY ~An emerald... yes, an emerald would rather enhance the colour of my eyes- how good of you to notice! An emerald will do very well.~
= ~Of course, this means I don't have to carry around all these other rocks... they merely weigh me down. I don't suppose you want them?~
= ~You may do with them what you will. Clunky things, most of them.~
IF ~~ THEN DO ~GiveItemCreate("HELM19",Player1,0,0,0)   // Ioun
				GiveItemCreate("MISC36",Player1,0,0,0)   // Pearl
				GiveItemCreate("MINC34",Player1,0,0,0)  // Garnet
				GiveItemCreate("MISC42",Player1,0,0,0)  // Diamond
				GiveItemCreate("AMUL12",Player1,0,0,0)  // Laeral's tear
				GiveItemCreate("MISC41",Player1,0,0,0) // Sapphire
				~ GOTO Rewards
END

IF ~~ sapphire
SAY ~A sapphire... yes, it will set off my dress. Have you noticed it is of the latest cut? And the colour is quite unique.~
= ~Of course, this means I don't have to carry around all these other rocks... they merely weigh me down. I don't suppose you want them?~
= ~You may do with them what you will. Clunky things, most of them.~
IF ~~ THEN DO ~GiveItemCreate("HELM19",Player1,0,0,0)   // Ioun
				GiveItemCreate("MISC36",Player1,0,0,0)   // Pearl
				GiveItemCreate("MINC34",Player1,0,0,0)  // Garnet
				GiveItemCreate("MISC42",Player1,0,0,0)  // Diamond
				GiveItemCreate("MISC43",Player1,0,0,0)  // Emerald
				GiveItemCreate("AMUL12",Player1,0,0,0)  // Laeral's tear
				~ GOTO Rewards
END

IF ~~ laeral
SAY ~Your friend is insightful indeed. A Laeral's Tear, though perhaps a little on the tawdry side, truly embodies my nature. How perfect. Beautiful, unassuming, yet intrinsically magical.~
= ~I suppose it means that I don't have to carry around all these other rocks. They merely weigh me down. Do with them what you will.~
IF ~~ THEN DO ~GiveItemCreate("HELM19",Player1,0,0,0)   // Ioun
				GiveItemCreate("MISC36",Player1,0,0,0)   // Pearl
				GiveItemCreate("MINC34",Player1,0,0,0)  // Garnet
				GiveItemCreate("MISC42",Player1,0,0,0)  // Diamond
				GiveItemCreate("MISC43",Player1,0,0,0)  // Emerald
				GiveItemCreate("MISC41",Player1,0,0,0) // Sapphire
				~ GOTO Rewards
END

IF ~~ THEN Wrong2
SAY ~Wrong. The answer was a cabbage. Even I knew that, and I've never eaten something so plain as cabbage!~
= ~One more chance for you.~
IF ~~ THEN EXTERN WWELLE Question3
END

IF ~~ Rewards
SAY ~I tire of this riddle business and so, I suspect, do you.~
IF ~GGT("WWEllyQuestions",1)~ THEN DO ~ActionOverride("Minsc",ReallyForceSpellRES("wwboo",Myself))~ EXTERN WWELLE NotAFool
IF ~!GGT("WWEllyQuestions",1)~ THEN EXTERN WWELLE CompleteFool
END


IF ~~ NotAFool
SAY ~I gladly return 'Boo' to you (Pootles suits him much better, I dare say). He keeps stealing my crackers.~
IF ~OR(2)
	G("WWEllyQuestions",6)
	G("WWEllyQuestions",5)~ THEN EXTERN WWELLE UltimateReward      // Boolet, 20,000 xp
IF ~OR(2)
	G("WWEllyQuestions",4)
	G("WWEllyQuestions",3)~ THEN EXTERN WWELLE Niceish  	// Boolet, 15,000 xp
IF ~OR(2)
	G("WWEllyQuestions",2)
	G("WWEllyQuestions",1)~ THEN EXTERN WWELLE Minor		// Boolet, 10,000 xp
END

IF ~~ Niceish
SAY ~You are not such a bad creature yourself. Your answers to my riddles were... tolerable, I suppose. Then again, not everybody has had my education.~
= ~Here, take this plaything. The little hamster took a shine to it, and I hate to see friends parted. As for yoursef, all you need now, is thorough training in ettiquette and perhaps a long bath. Then you might even be fit to act as a De'Lyl guardsman or housekeeper- a compliment indeed.~
= ~But do not aim too high, either. It is not good to overstep oneself.~
IF ~~ THEN DO ~GiveItemCreate("MISC3F","Minsc",0,1,1)~ EXTERN WWELLE Compliment
END

IF ~~ Minor
SAY ~You are not such a bad creature yourself, though some of your answers to my questions were... appalling to say the least. But I suppose not everybody has had my education.~
= ~In fact, I wonder how 'Boo' should fare in the hands of somebody blessed with as little intelligence as yourself. It is no matter. I wash my hands of him. Quite literally. You, sir, really need to toilet train this hamster.~
= ~Good day.~
IF ~~ THEN DO ~ActionOverride("Minsc",ReallyForceSpellRES("wwboo",Myself))
				AddexperienceParty(10000)
				SetGlobal("WWBooGone","GLOBAL",2)
				ActionOverride("Minsc",ChangeAIScript("wwbant",OVERRIDE))
				EscapeArea()~ EXIT
END


IF ~~ CompleteFool
SAY ~I shall not return Boo to you. He would be unsafe in the hands of an imbecile such as yourself. Your answers to my questions were quite frankly, appalling.~
= ~You have wasted enough of my time. Good day.~
IF ~~ THEN EXTERN MINSCJ ThreatenElly
END

IF ~~ UltimateReward
SAY ~The De'Lyls are not too proud to admit their mistakes. I was mistaken about you. Perhaps it is the sad state of your clothing that misled me.~
= ~But you have proven yourself worthy of my notice. Here, I shall even compete my spell on Poot- nay, 'Boo', for you. Be grateful for this opportunity... it is not everyday that you shall spy a talent such as mine.~
IF ~~ THEN DO ~ClearAllActions()
				StartCutSceneMode()
				StartCutScene("wwelspl")~ EXIT
END



// Start the wizards too
BEGIN ~WWCOWL1~
BEGIN ~WWCOWL2~

///////////////////////
/* CHAINs begin here */
///////////////////////

CHAIN
IF ~~ THEN MINSCJ AccuseStealBoo
~Who is so evil that he would take Boo from his Minsc?!~
DO ~SetGlobal("WWMinscAccusePC","LOCALS",3)~
== MINSCJ IF ~IsValidForPartyDialog("Jan")~ THEN ~You! It was you, little man, who has taken my Boo away! I have seen how your beady eyes stare at him with longing!~
== JANJ IF ~IsValidForPartyDialog("Jan")~ THEN ~What can I say? I was hungry.~
== MINSCJ IF ~IsValidForPartyDialog("Jan")~ THEN ~So the terrible gnome admits his guilt!~
== JANJ IF ~IsValidForPartyDialog("Jan")~ THEN ~Oh, no no no. I didn't take the poor guy, Minscy. Although now I wish I had. That's quite the shade of purple you have, there.~
== MINSCJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~It was you, dwarf! I know of you and your eeeeeevil ways! Return my Boo at once or justice shall be planted firmly on your teeny skull!~
== KORGANJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~Hmph. Are ye sure ye just didn't roll over the wee vermin in yer sleep, ye blasted oaf?~
== MINSCJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~Vile lies! Vile, terrible...and with disturbing imagery, too...lies!~
== MINSCJ IF ~IsValidForPartyDialog("HaerDalis")~ THEN ~It was you, actor! You have taken my Boo!~
== HAERDAJ IF ~IsValidForPartyDialog("HaerDalis")~ THEN ~That's quite an imagination you have, my angry titmouse. What would I do with your little companion?~
== MINSCJ IF ~IsValidForPartyDialog("HaerDalis")~ THEN ~Minsc knows! You cannot lie! Minsc knows of your lurid ways!~
== HAERDAJ IF ~IsValidForPartyDialog("HaerDalis")~ THEN ~Hmmm...was I talking in my sleep again?~
== MINSCJ IF ~IsValidForPartyDialog("Edwin") Gender("Edwin",MALE)~ THEN ~YOU have done this, you evil, despicable red wizard! You were not content with taunting Dynaheir and now you take Boo from me as well!~
== EDWINJ IF ~IsValidForPartyDialog("Edwin") Gender("Edwin",MALE)~ THEN ~The thought has crossed my mind that the addition of a little hamster fur to my robe would make its charms quite complete. Nothing tasteless, just enough to accentuate my perfect features. (Necromancy might be my specialty, but Enchanter would be a fitting description as well.)~
== MINSCJ IF ~IsValidForPartyDialog("Edwin") Gender("Edwin",MALE)~ THEN ~You - you have added Boo's WHAT to your robe?!~
== EDWINJ IF ~IsValidForPartyDialog("Edwin") Gender("Edwin",MALE)~ THEN ~Calm yourself, great gorilla, no hamster fur decorates these robes. (Ermine is eminently more suitable for a wizard of my standing.) I decided that the inevitable fleabites were not worth the effect. (Not to mention ringworm. It would explain that ridiculous circle on the great oaf's head, at any rate.)~
== MINSCJ IF ~IsValidForPartyDialog("Edwin") Gender("Edwin",FEMALE)~ THEN ~Cou- could YOU have done this, pretty lady? I know that pretty ladies sometimes play jokes on men, but this is too much!~
== BEDWINWO IF ~IsValidForPartyDialog("Edwin") Gender("Edwin",FEMALE)~ THEN ~Be glad that I haven't burnt you to a cinder for calling me 'pretty', you gorilla-brained son of a monkey. I wouldn't touch your hamster if it was the last rodent in Faerun! (Am I pouting? Gods, I think I am pouting.)~
== MINSCJ IF ~IsValidForPartyDialog("Edwin") Gender("Edwin",FEMALE)~ THEN ~I am sorry, dear lady, I have brought a tear to your eye. Please, Minsc will give you a great heroic hug and make you all better!~
== BEDWINWO IF ~IsValidForPartyDialog("Edwin") Gender("Edwin",FEMALE)~ THEN ~Unhand me at once, you banana-breathed freak of a- a- (Curse you, traitor of a stomach! I will have NO butterflies in there, not a single one!)~
== MINSCJ IF ~IsValidForPartyDialog("Edwin") Gender("Edwin",FEMALE)~ THEN ~There, see? Minsc has made it all better. Ooh, you are nearly as red as your robe! It makes you more pretty than ever before! But I am forgetting myself. And Boo! Oh Boo, where are you? Who has taken you? It was... it was...~
== MINSCJ ~It was you, <CHARNAME>! All this time you have been envying Minsc of his rapport with great Boo! You wish the title of Great Hero all for yourself!~
END
++ ~You have *got* to be kidding.~ GOTO BooKidding
++ ~Yes, yes, it was me all along. Listen to my gleeful laughter.~ GOTO BooLaughter

CHAIN
IF ~Global("MinscDies","GLOBAL",91)~ THEN BMINSC miracle
~Minsc...Minsc breaths! A miracle this is!~
DO ~SetGlobal("MinscDies","GLOBAL",2)~
== BKELDOR ~That it is, Minsc.  Do not waste it, for life anew is not a right, but a privilege granted.  I need not tell you to rededicate your life to fighting the good fight.  I imagine there is little else you would choose to do.~
== BMINSC ~Besides the quest to find little Boo! This new life will grant me the strength to do so! Beware evil, Minsc lives!!~
EXIT

CHAIN
IF ~InParty("Edwin")
	See("Edwin")
	Gender("Edwin",FEMALE)
	!StateCheck("Edwin",STATE_SLEEPING)
	Global("BMinsc10","LOCALS",90)~ THEN BMINSC scoundrel
~I do not understand.  It is not as though the scoundrel will be missed, but where has Edwin gone and who is this woman that wears his clothes?~
DO ~SetGlobal("BMinsc10","LOCALS",1)~
== BEDWINWO ~I will not be scrutinized in this way!  Mind your own concerns, you stone-headed oaf!~
== BMINSC ~Such a temperament!  Fire in her belly and not afraid to spit in an eye!  It reminds me of the fighting women of my homeland!  If only little Boo were here to admire you as well.  Ah sweet lady, you bring me tears.~
== BEDWINWO ~Tears indeed!  Stand away lest I bring you a fireball as well!  (Such suffering I must endure!  The pain behind my eyes does grow steadily!)~
EXIT

CHAIN
IF ~InParty("Minsc")
	See("Minsc")
	!StateCheck("Minsc",STATE_SLEEPING)
	Gender("Edwin",FEMALE)
	Global("EdwinW2","LOCALS",90)~ THEN BEDWINWO scoundrel2
~What!?  Why do you stare at me so, barbarian?!~
DO ~SetGlobal("EdwinW2","LOCALS",2)~
== BMINSC ~You bear handsome features, though they are familiar, too.  Edwin's sister perhaps?  You are his superior in your manner though.~
== BEDWINWO ~I AM Edwin, you lumbering fool!  Can you not comprehend this?!~
== BMINSC ~I don't do well with the philosophical. You are Edwin? Ah, like Minsc is Boo and Boo is Minsc because we carry each other within.  Do you like hamsters?  I think Boo would like you. If he were here, he would surely be blushing, pretty lady!~
= ~In fact... Minsc will recite a poem to you, yes?~
== BEDWINWO ~Nooo, please, noooo!!~
== BMINSC ~Oh do not protest so. Minsc does not mind- Boo would want him to do this.~
= ~Lady in red, most fiery and fair,~
= ~You have Edwin's nose and some of his hair...~
= ~Though your temper is large and your anger quite free,~
= ~You look so much better in his robes than does he!~
= ~What do you think, pretty lady? Would Minsc make a heroic bard as well as heroic ranger?~
== BEDWINWO ~(I will kill ALL of them.  Slowly.  With...with HOT...pokey things and...and coals and...and prods.  Yessssss, prods.  Many, many prods.)~
EXIT

CHAIN
IF WEIGHT #-46 ~Global("WWBooGone","GLOBAL",1)
	AreaCheck("AR0300")
	Global("WWDocksComment","LOCALS",0)~ THEN MINSCJ SomeoneSeenBoo
~Someone must know... Someone must have seen! We must track down Boo's trail even if we must inspect every hamster dropping in this great city!~
DO ~SetGlobal("WWDocksComment","LOCALS",1)~
== NALIAJ IF ~!IsValidForPartyDialog("Aerie")
			  IsValidForPartyDialog("Nalia")~ THEN ~Uhhh... Minsc, I don't think that's a hamster dropping...~
== AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~No, Minsc! Don't touch that! It's not a hamster dropping!~
== MINSCJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~You are right Aerie. My eyes are not seeing as well as they should be. It... it is the dim light (sniff).~
== JANJ IF ~IsValidForPartyDialog("Jan")
			  IsValidForPartyDialog("Aerie")
			  TimeOfDay(DAY)~ THEN ~Looks like broad daylight to me.~
== AERIEJ IF ~IsValidForPartyDialog("Jan")
			  IsValidForPartyDialog("Aerie")
			  TimeOfDay(DAY)~ THEN ~Oh hush, Jan.~
== AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~Minsc, you can wipe your eyes on my sleeve if- if you want to.~
== MINSCJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~NO!! I am not crying! Great heroes and rangers do not shed tears, except maybe when faced with very strong onions! I must be allergic to fish! Or pirates!!~
== JANJ IF ~IsValidForPartyDialog("Aerie")
            IsValidForPartyDialog("Jan")~ THEN ~Well that's a new one. Which part? The hook? The scimitar?~
== MINSCJ IF ~IsValidForPartyDialog("Aerie")
            IsValidForPartyDialog("Jan")~ THEN ~You are rude, little gnome! Perhaps I am allergic to YOU!! I will blow my nose on your villainy and boot you back to your tiny house where you will tease Minsc no longer!!~
== JANJ IF ~IsValidForPartyDialog("Aerie")
            IsValidForPartyDialog("Jan")~ THEN ~Well, just make sure I don't land in my turnip patch. Nothing worse than the waste of a good turnip... except for spilled turnip stew. The thought of that brings a tear to my eye, it does... Aerie, come over here, would you? ~
== AERIEJ IF ~IsValidForPartyDialog("Jan")
			  IsValidForPartyDialog("Aerie")~ THEN ~Wh-what are you doing Jan? Are you trying to blow your nose on my sleeve?! Ick! Get away!!~
== JANJ IF ~IsValidForPartyDialog("Jan")
			  IsValidForPartyDialog("Aerie")~ THEN ~Ah, you're cruel to an old gnome, Aerie.~
EXIT

CHAIN
IF ~!G("WWBillyHelp",1)~ THEN WWDEL Rudeness
~Don't be interrupting me. I'm thinking.~
== WWEFF ~Har! You a thinker now, Delag? Such a sight would make your momma proud if you weren't lyin'.~
== WWDEL IF ~!Dead("WWEff")~ THEN ~Not lying, but NOW I'm thinking of bashing your skull in. Or tying a knot in your tongue.~
== WWVIVI IF ~!Dead("WWEff")
			  !Dead("WWDel")~ THEN ~Quiet, you lot! We'll be throwned out soonish if you keep that rabble up!~
EXIT

// wweff is DV  wwthug is Override

CHAIN
IF ~!G("WWBillyHelp",1)~ THEN WWEFF Rudeness2
~These nobs do have it good. 'Tis cosy warm up on the second level. If the tavern master don't lock his doors, that's his problem.~
== WWSTEN ~Warm you may be, Eforf, but I'd prefer if the tavern master didn't lock his barrels.~
== WWEFF IF ~!Dead("WWSten")~ THEN ~Ah, you'd be right, Sten. A good ale would warm me up as quick.~
EXIT

// wwsten is DV wwthug is Override

CHAIN
IF ~!G("WWBillyHelp",1)~ THEN WWSTEN Rudeness3
~An ale would be nice. Why're we up on the poncy level again?~
DO ~SetGlobal("WWKnockers","LOCALS",1)~
== WWVIVI ~I don't rightly know.~
== WWDEL IF ~!Dead("WWVivi")~ THEN ~We took us a wrong turn at the stairs, Delag thinks.~
== WWEFF IF ~!Dead("WWDel")~ THEN ~Cursed 'down' and 'up'! Which was which again?~
== WWSTEN IF ~!Dead("WWSten")
			  !Dead("WWEff")~ THEN ~Ah, is warm at any rate, and the knockers on the nobles is well worth seein', I reckon.~
EXIT

CHAIN
IF ~!G("WWBillyHelp",1)~ THEN WWVIVI Rudeness4
~So... whaten reason are you poken Vivick, eh?~
== WWDEL ~You should give him a right clout, Delag thinks.~
== WWSTEN IF ~!Dead("WWDel")~ THEN ~Naww, relax, Vivick, an' clout Delag instead.~
== WWDEL IF ~!Dead("WWSten")~ THEN ~I'll clout YOU, you rascal!~
== WWVIVI IF ~!Dead("WWSten")~ THEN ~Oi! I clout who I want! Quiet, you.~
EXIT

CHAIN
IF WEIGHT #-3 ~Global("WWFightVivickNow","GLOBAL",2)~ THEN WWVIVI VivickLoses
~All right! All right! That's enough! A good fight and you've beaten me fairs enough.~
= ~Billy, open that hole in your head and tells these people here what's happened to their shrew, likes.~
== BMINSC ~Shrew? No, Boo is a hamster!~
== WWVIVI ~Billy?~
END
IF ~~ THEN EXTERN WWBILL Yapper

CHAIN
IF ~Global("WWCowlInterrupt","GLOBAL",1)~ THEN WWCOWL1 Unsanctioned
~The practise of magic without a- ~
DO ~SetGlobal("WWCowlInterrupt","GLOBAL",2)~
= ~Wait, it is Lady De'Lyl, is it not?~
== WWCOWL2 ~Yes, it is. Uh oh.~
== WWELLE ~I PAID for my license a month ago! Don't you wizards keep records of such things?~
== WWCOWL1 ~We do, Lady De'Lyl. Do forgive us.~
== WWCOWL2 ~Yes, we humbly beg pardon.~
== WWELLE ~I will this time. Just don't let it happen again. And now, if you'll excuse me, I'm just about to remove these troublemakers from this district for you.~
= ~Or did you want to stay around and watch the show?~
== WWCOWL2 ~Oh no! We will leave you to your work. And if I may say so, your magic is coming along nicely.~
== WWCOWL1 ~And greetings to Lord De'Lyl.~
== WWCOWL2 ~Sorry again for interrupting you, Lady De'Lyl.~
END
IF ~~ THEN DO ~ClearAllActions()
				StartCutScene("WWcowl")~ EXIT

CHAIN
IF ~G("WWCowledAppearance",2)~ THEN WWCOWL1 EllyTakeDown
~It is a good thing we kept watch on this little corner of Athkatla.~
DO ~SG("WWCowledAppearance",5)~
== WWCOWL2 ~Indeed.~
== WWCOWL1 ~You've accomplished a great task in ridding this district of Eleanya De'Lyl.~
== WWCOWL2 ~We cannot thank you enough. She has been quite the little pest.~
== WWCOWL1 ~Quite.~
== WWCOWL2 ~How can we reward you for your efforts?~
== VALYGARJ IF ~IsValidForPartyDialog("Valygar")~ THEN ~Do not take anything that these wizards offer. Any reward they grant must be loaded with hidden agenda.~
== WWCOWL1 IF ~IsValidForPartyDialog("Valygar")~ THEN ~Silence, dog!~
== WWCOWL1 IF ~IsValidForPartyDialog("Valygar")~ THEN ~Hmm. Dog you may be, yet you look familiar somehow. No, it must be a trick the light plays on me. Ah, slink away then.~
END
IF ~!G("BribedCowled",1)~ THEN EXTERN WWCOWL2 license
IF ~G("BribedCowled",1)~ THEN EXTERN WWCOWL2 gotlicense

CHAIN
IF ~~ THEN WWCOWL2 gotlicense
~Hmm. You have purchased a license to practise magic in the city, have you not?~
END
++ ~That is correct.~ EXTERN WWCOWL1 givemoney
++ ~It is no business of yours.~ EXTERN WWCOWL1 asyouwish2
++ ~Do you know anything about a mage named Irenicus?~ EXTERN WWCOWL1 irenicus2
++ ~You or other members of your organisation have captured Imoen. Where is she?~  EXTERN WWCOWL1 irenicus2
++ ~I care not. Leave at once.~ EXTERN WWCOWL1 asyouwish

CHAIN
IF ~~ THEN WWCOWL2 license
~Hmm. You, <SIRMAAM>, do not currently possess a license to practise magic in the city, do you?~
END
++ ~That is correct.~ EXTERN WWCOWL1 givelicense
++ ~It is no business of yours.~ EXTERN WWCOWL1 asyouwish2
++ ~Do you know anything about a mage named Irenicus?~ EXTERN WWCOWL1 irenicus
++ ~You or other members of your organisation have captured Imoen. Where is she?~  EXTERN WWCOWL1 irenicus
++ ~I care not. Leave at once.~ EXTERN WWCOWL1 asyouwish

CHAIN
IF ~~ THEN WWCOWL1 givemoney
~And the license was purchased at the cost of 1000 gold?~
END
++ ~It was 10,000 gold, actually.~ EXTERN WWCOWL2 10000
++ ~It was 5000 gold, actually.~ EXTERN WWCOWL2 5000


CHAIN
IF ~~ THEN WWCOWL2 10000
~10,000 gold? No wonder you look so ragged. We must have a word with Corneil about this.~
== WWCOWL1 ~In the meantime, we will tide you over with... 1000 gold? Will that do?~
== WWCOWL2 ~It will do nicely.~
== WWCOWL1 ~Here you are. Don't spend it all at once. Though if you must, try visiting a goodshouse instead of an alehouse, would you?~
== WWCOWL2 ~Farewell.~
END
IF ~~ THEN DO ~GivePartyGold(1000)
				ClearAllActions()
				CreateVisualEffectObject("SPDIMNDR","WWCowl2")
				Wait(1)
				ActionOverride("WWCowl2",DestroySelf())
				CreateVisualEffectObject("SPDIMNDR",Myself)
				Wait(1)
				DestroySelf()~ EXIT

CHAIN
IF ~~ THEN WWCOWL2 5000
~Yes, just as I had thought. *1000* gold.~
== WWCOWL1 ~A tidy sum. Corneil's prices are well within reason.~
== WWCOWL2 ~Here you are. Don't spend it all at once. Though if you must, try visiting a goodshouse instead of an alehouse, would you?~
== WWCOWL2 ~Farewell.~
END
IF ~~ THEN DO ~GivePartyGold(1000)
				ClearAllActions()
				CreateVisualEffectObject("SPDIMNDR","WWCowl2")
				Wait(1)
				ActionOverride("WWCowl2",DestroySelf())
				CreateVisualEffectObject("SPDIMNDR",Myself)
				Wait(1)
				DestroySelf()~ EXIT


CHAIN
IF ~~ THEN WWCOWL1 givelicense
~We should perhaps inform Corneil of the situation...~
== WWCOWL2 ~Just as a token of our appreciation. Expect no more from us.~
== WWCOWL1 ~Indeed.~
== WWCOWL1 ~But be warned- use your magic unwisely and the license will be taken from you. Good day to you.~
END
IF ~~ THEN DO 	~SG("BribedCowled",1)
				ClearAllActions()
				CreateVisualEffectObject("SPDIMNDR","WWCowl2")
				Wait(1)
				ActionOverride("WWCowl2",DestroySelf())
				CreateVisualEffectObject("SPDIMNDR",Myself)
				Wait(1)
				DestroySelf()~ EXIT

CHAIN
IF ~~ THEN WWCOWL1 irenicus
~That is not what we are here to discuss.~
= ~Do you, or do you not possess a license to practise magic in the city?~
END
++ ~I do not.~ EXTERN WWCOWL1 givelicense
++ ~It is no business of yours.~ EXTERN WWCOWL1 asyouwish2
++ ~I care not. Leave at once.~ EXTERN WWCOWL1 asyouwish

CHAIN
IF ~~ THEN WWCOWL1 irenicus2
~That is not what we are here to discuss.~
= ~Have you purchased a magic license?~
END
++ ~I have.~ EXTERN WWCOWL1 givemoney
++ ~It is no business of yours.~ EXTERN WWCOWL1 asyouwish2
++ ~I care not. Leave at once.~ EXTERN WWCOWL1 asyouwish

CHAIN
IF ~~ THEN WWCOWL1 asyouwish
~If that is your will. Good day.~
END
IF ~~ THEN DO ~ClearAllActions()
				CreateVisualEffectObject("SPDIMNDR","WWCowl2")
				Wait(1)
				ActionOverride("WWCowl2",DestroySelf())
				CreateVisualEffectObject("SPDIMNDR",Myself)
				Wait(1)
				DestroySelf()~ EXIT

CHAIN
IF ~~ THEN WWCOWL1 asyouwish2
~If that is the way you must have it. It is no wonder that deviants run through the streets when the general populace is so... unpleasant.~
END
IF ~~ THEN DO ~ClearAllActions()
				CreateVisualEffectObject("SPDIMNDR","WWCowl2")
				Wait(1)
				ActionOverride("WWCowl2",DestroySelf())
				CreateVisualEffectObject("SPDIMNDR",Myself)
				Wait(1)
				DestroySelf()~ EXIT


CHAIN
IF ~~ THEN WWVIVI OuttaTheWay
~While I'm no great fan of childers, 'specially filthy ones like that one, I can't let you attack an innocent boy! Leave now or me and me mates will be fighting you proper! Teach you some manners, we will!~
== WWEFF IF ~!Dead("WWEff")~ THEN ~Yah, don't think we won't!~
== WWSTEN IF ~!Dead("WWSten")~ THEN ~Yeh, you tell 'em, Vivick.~
== WWDEL IF ~!Dead("WWDel")~ THEN ~Attacking chillun, you should be ashamed, Delag says.~
END
++ ~That child is no innocent! He stole something very important to us.~ + ThiefBilly
++ ~Well we're not leaving, so I guess your life is over!~ + FightVivic

CHAIN
IF ~~ THEN WWVIVI FightVivic
~I warned you! Fellas, get ready for a brawl!~
== WWEFF IF ~!Dead("WWEff")~ THEN ~Now THIS'll warm me up good!~
== WWSTEN IF ~!Dead("WWSten") Global("WWKnockers","LOCALS",0)~ THEN ~Make this quick m'lads, there's barrels waitin' for us downstairs!~
== WWSTEN IF ~!Dead("WWSten") Global("WWKnockers","LOCALS",1)~ THEN ~Make this quick m'lads, there's knockers waitin' to be seen!~
== WWDEL IF ~!Dead("WWDel")~ THEN ~Och, Delag just wanted to be thinking, without you lot barging in!~
== WWVIVI IF ~!Dead("WWVivi")~ THEN ~No more talking, lads! Swords up!~
END
IF ~~ THEN DO ~
		SetGlobal("WWThugFight","GLOBAL",1)
		ActionOverride("WWBill",MoveToPoint([818.360]))
		ActionOverride("WWEff",Enemy())
		ActionOverride("WWSten",Enemy())
		ActionOverride("WWDel",Enemy())
		ActionOverride("WWVivi",Enemy())~ EXIT

CHAIN
IF ~~ THEN WWVIVI ThiefBilly
~Now what's this about thieving? We won't be harbourin' crims, eh, boy? Explain yourself!~
== WWBILL ~I.. uh-~
== WWVIVI ~Someone set us straight here! You, <MANWOMAN>- why were you chasing this boy?~
END
++ ~I'd like to hear this boy admit to his crime!~ EXTERN WWBILL BillyExplain
++ ~Minsc? Would you like to explain?~ EXTERN MINSCJ MinscExplain
++ ~Our- uh- hamster was stolen. A hamster named Boo.~ + Laughs

CHAIN
IF ~~ THEN WWBill BillyExplain
~I'm not admitting to no crime! The big man had a funny looking rat with him. It was sad and all squashed-looking, so I took it!~
== MINSCJ ~Boo is NEVER sad to be with his Minsc! And Boo is a hamster and not at all squashed looking! In fact, he is so rotund that he causes squirrels everywhere to feel great envy.~
END
IF ~~ THEN EXTERN WWVivi Laughs


CHAIN
IF ~~ THEN WWVIVI Laughs
~Your HAMSTER was stolen? *That's* what this is about?! Some hamster named Boo?!~
== WWEFF IF ~!Dead("WWEff")~ THEN ~Hey Vivick, perhaps they're worried he'll have a *furry* hard time away from his owner!~
== WWVIVI ~(Snigger)~
== WWSTEN IF ~!Dead("WWSten") !Dead("WWEff")~ THEN ~Harhar!!  It mouse be hard keeping a hamster that rodent stay at home!~
== WWEFF IF ~!Dead("WWEff") !Dead("WWSten")~ THEN ~Haha!~
== WWDEL IF ~!Dead("WWDel")~ THEN ~(snicker) It brings a tear to my eye! In fact Delag will cry now! BOO hoo!!~
== WWVIVI IF ~!Dead("WWEff")~ THEN ~That's enough, fellas! Have some sensitivities, eh? Not one more (snigger) SQUEAK out of you lot!~
== WWEFF IF ~!Dead("WWEff")~ THEN ~HAHAHAA!!~
== WWSTEN IF ~!Dead("WWSten")~ THEN ~HOHOOHOOHOO!!~
== WWDEL IF ~!Dead("WWDel")~ THEN ~HEHEHEHEEEHEEE!!~
== MINSCJ ~You... you all dare LAUGH at Minsc's plight?!!~
= ~RRAAARRR-~
= ~RRAARRRRGG-~
= ~RRAAARRRGGHHHH!! FEEL the anger of Minsc as it boils through his veins!! SEE the great beserker rage build up in Minsc's eyes!!~
= ~TASTE the steely blade of justice poking into your eeevil laughter!!! Gather your swords!! Minsc and his great buttkicking friend <CHARNAME> will cut down every one of your stinking smirks with heroic might!! RRAAARRRRGHHHH!!!~
= ~BUTTKICKING FOR-~
END
++ ~Calm yourself, Minsc! We do not want to shed blood needlessly.~ EXTERN MINSCJ MinscReconsiders
++ ~That's enough Minsc! Killing them won't help you find Boo.~ EXTERN MINSCJ MinscReconsiders
++ ~Go on Minsc! Boo would be proud of your actions.~ EXTERN MINSCJ MinscReconsiders


CHAIN
IF ~~ THEN WWVIVI NoReason
~Well, tell you what- I'm getting bored in the brainhole up here. Give us a decent fight and if you winnen, then I make Billy talk. If you lose, then you'll have given me entertainment anyway. What say you?~
== MINSCJ ~Yes! Minsc will fight as he has never fought before! Boo is on the line!!~
END
++ ~Wait Minsc! Will you allow your great heroic friend to take your place in defending Boo's honour?~ DO ~SetGlobal("WWFightVivick","GLOBAL",2)~ EXTERN MINSCJ DoThis
++ ~Good luck, Minsc.~ DO ~SetGlobal("WWFightVivick","GLOBAL",1)~ EXTERN MINSCJ PreFight
++ ~A decent fight, eh? I'll give you one right now! Die, fool!~ EXTERN WWVIVI FightVivic

CHAIN
IF ~~ THEN WWVIVI 50Gold
~50 gold, eh? Tell you what- I'm getting bored in the brainhole up here. Give us a decent fight and use your gold for wageren'. Win and I'll get Billy to ope' his mouth for you. Lose and I'll be a richer man. What say you?~
== WWEFF IF ~!Dead("WWEff")~ THEN ~Are you sure about this Vivick? That ain't your rat. Hells, that kid ain't even your kid!~
== WWVIVI IF ~!Dead("WWEff")~ THEN ~Yes lad. I'm bored to me bone up here.~
== WWSTEN IF ~!Dead("WWSten")~ THEN ~If you gotta do some fightin', don't scare off the noble ladies, Vivick, is all I'm askin'.~
== WWVIVI IF ~!Dead("WWSten")~ THEN ~(Sigh.)~
== WWVIVI ~What do you say? A fight, friendly like?~
== MINSCJ ~Yes! Minsc will fight as he has never fought before! Boo is on the line!!~
END
++ ~Wait Minsc! Will you allow your great heroic friend to take your place in defending Boo's honour?~ DO ~SetGlobal("WWFightVivick","GLOBAL",2)~ EXTERN MINSCJ DoThis
++ ~Good luck, Minsc.~ DO ~SetGlobal("WWFightVivick","GLOBAL",1)~ EXTERN MINSCJ PreFight
++ ~A decent fight, eh? I'll give you one right now! Die, fool!~ EXTERN WWVIVI FightVivic

CHAIN
IF ~~ THEN MINSCJ DoThis
~<CHARNAME> would do such a thing for Boo? Truly, you are the greatest of heroes! Tales will be told of the day that Boo's great non-hamster friend came in to save his little furry behind!~
= ~I will let Boo know of this when we rescue him. Many grateful hamster kisses will be bestowed, of this Minsc is quite sure!~
== WWVIVI ~I'll take 50 gold if I win, then. Remember, we're going friendly here, not to the deaths, right?~
END
+ ~Global("WWFightVivick","GLOBAL",1)
   !HPPercent("Minsc",100)~ + ~You'll have to let Minsc heal up first. It won't be fair otherwise.~ EXTERN WWVIVI Warning2Heal
+ ~Global("WWFightVivick","GLOBAL",2)
   !HPPercent([PC],100)~ + ~I'll have to heal up first. It won't be a fair fight otherwise.~ EXTERN WWVIVI  Warning2Heal
+ ~Global("WWFightVivick","GLOBAL",1)
   HPPercent("Minsc",100)~ + ~Right you are! Go for the eyes, Minsc!~ EXTERN WWVIVI  QuickFight
+ ~Global("WWFightVivick","GLOBAL",2)
   HPPercent([PC],100)~ + ~Certainly. I'm ready.~ EXTERN WWVIVI  QuickFight
+ ~Global("WWFightVivick","GLOBAL",1)~ + ~We'll come back later, when we're ready.~ EXTERN WWVIVI ComeLater
+ ~Global("WWFightVivick","GLOBAL",2)~ + ~I'll come back later, when I'm ready.~ EXTERN WWVIVI ComeLater
++ ~I'd prefer to the death. Right now, if you please.~ EXTERN WWVIVI FightVivic

CHAIN
IF ~~ THEN WWVIVI ComeLater
~Sure, sure. Just don't take too long else I fallen' asleep.~
DO ~SetGlobal("WWFightVivickNow","GLOBAL",0)~
EXIT

CHAIN
IF ~~ THEN MINSCJ PreFight
~It will bring tears to the eyes of hamsters and heroes everywhere to see how hard Minsc hits this man! For Boo! And justice! Though more for Boo than justice!~
== WWVIVI ~Uh.. sure. I'll take 50 gold if I win, then. Remember, we're going friendly here, not to the deaths, right?~
END
+ ~Global("WWFightVivick","GLOBAL",1)
   !HPPercent("Minsc",100)~ + ~You'll have to let Minsc heal up first. It won't be fair otherwise.~ EXTERN WWVIVI Warning2Heal
+ ~Global("WWFightVivick","GLOBAL",2)
   !HPPercent([PC],100)~ + ~I'll have to heal up first. It won't be a fair fight otherwise.~ EXTERN WWVIVI  Warning2Heal
+ ~Global("WWFightVivick","GLOBAL",1)
   HPPercent("Minsc",100)~ + ~Right you are! Go for the eyes, Minsc!~ EXTERN WWVIVI  QuickFight
+ ~Global("WWFightVivick","GLOBAL",2)
   HPPercent([PC],100)~ + ~Certainly. I'm ready.~ EXTERN WWVIVI  QuickFight
++ ~We're not ready yet. We'll come back later.~ EXTERN WWVIVI ComeLater
++ ~I'd prefer to the death. Right now, if you please.~ EXTERN WWVIVI FightVivic

CHAIN
IF ~~ THEN WWBILL Yapper
~YOU'RE MEAN TOO, MISTER!!~
== WWVIVI ~Good you recognisen that. I WILL wallop you a good one if you don't tell what's happened to this fella's mouse.~
== MINSCJ ~HAMSTER!~
== WWVIVI ~Whatever.~
== MINSCJ ~You would not be saying that, nasty man, if you could feel Boo's wrathful gaze centred on your chest!~
== WWVIVI ~Be more like centred on me ankles, I'd say. Stop interrupting, less you don't wanten' your gerbil back.~
== MINSCJ ~(Is it so hard to remember that Boo is a GIANT SPACE HAMSTER?!)~
== EDWINJ IF ~IsValidForPartyDialogue("Edwin")~ THEN ~(The last straw! This ridiculous oaf is now parroting me! But perhaps it is a sign of hero worship on his part. Yes, that must be it.)~
== WWVIVI ~Well, Billy?~
== WWBILL ~Oh, all right. I- I sold that little hamster of yours to a funny halfling man. I think his name was Smethy.~
END
IF ~~ THEN EXTERN MINSCJ SoldBooToHalfling

CHAIN
IF ~~ THEN MINSCJ SoldBooToHalfling
~You SOLD Boo?! To a funny halfling man?!~
= ~Boo is a heroic space hamster! He CANNOT be sold! But you have done it, little boy! Such villainy in so small a package, it makes Minsc quite pale with horror!~
= ~Evil seller-of-Boo, prepare to feel the justice of my boot as it connects with your backside, no matter how small you may be!~
== WWBILL ~Eek! Don't hurt me, mister! I'll take you to Smethy! He'll give your hamster back to you!~
== MINSCJ ~Yes, I will hold off my boot until Boo is back safely in my hands. But I will be watching you, little boy! Do not think that you can run away again!~
== WWBILL ~O- of course not, mister. Follow me.~
END
IF ~~ THEN DO ~SG("WWBillyHelp",10)
			ClearAllActions()
  			StartCutSceneMode()
			StartCutScene("wwsmet")~
EXIT

CHAIN
IF WEIGHT #-50 ~Global("WWSwooTalk","GLOBAL",1)~ THEN WWSWOO MorePetsBilly
~If it isn't little Billy again! Got any more fabulous animals for me, little one? Only the cleverest ones, mind!~
DO ~SetGlobal("WWSwooTalk","GLOBAL",2)~
== WWBILL IF ~NumInPartyAlive(2)~ THEN ~Yeah! I got two monkeys for ya!~
== WWBILL IF ~NumInPartyAlive(3)~ THEN ~Yeah! I got three monkeys for ya!~
== WWBILL IF ~NumInPartyAlive(4)~ THEN ~Yeah! I got four monkeys for ya!~
== WWBILL IF ~NumInPartyAlive(5)~ THEN ~Yeah! I got five monkeys for ya!~
== WWBILL IF ~NumInPartyAlive(6)~ THEN ~Yeah! I got six monkeys for ya!~
== EDWINJ IF ~IsValidForPartyDialog("Edwin")~ THEN ~That- that is *my* line!~
== WWBILL ~Bye mister!~
== EDWINJ IF ~IsValidForPartyDialog("Edwin")~ THEN ~Insolent bratling!~
END
IF ~~ THEN DO ~ClearAllActions()
  			StartCutSceneMode()
			StartCutScene("wwblve")~ EXIT

CHAIN
IF WEIGHT #-49 ~Global("WWSwooTalk","GLOBAL",2)
				Global("WWBillyGone","LOCALS",1)
				G("WWChatty",2)~ THEN WWSWOO SorryGuys
~Ah, that child has yet to learn some manners. Excellent source of stock, though, can't fault him there.~
DO ~SetGlobal("WWSwooTalk","GLOBAL",3)~
= ~Now, weary travellers... might you be looking for an animal companion or two? A gentle paw to comfort you on your travels?~
== MINSCJ ~This place is an outrage!! Why are these animals locked in cages so small? They have been denied their right to frolick! Minsc will free all the animals from this nasty man!~
= ~You, cow, will taste sweet clover once again! You, rabbit, will wave your tail in enjoyment out in the wild grasslands! You, chicken, will once again lay your eggs in inconvenient places! On this, Minsc swears!~
== CERNDJ IF ~IsValidForPartyDialogue("Cernd")~ THEN ~I must agree with you there, Minsc. It stings nature when her creatures are caged.~
== KORGANJ IF ~IsValidForPartyDialogue("Korgan")~ THEN ~I'll be stingin' ye in a moment if ye don't shut ye pansy mouth. Though ye'd more as likely take bein' called a 'pansy' a good thing.~
== WWSWOO ~Whoa there, large friend! The only animals in cages here are those that required it. See Chowder there? He'd be gobbling poor Flufftail quicksmart if I didn't put him in a cage. Now I'm not saying that cats and rabbit can't be friends, but they've got plenty to work out between them.~
== MINSCJ ~Hmm... If Boo were here, he would agree with you. Many a time his fur has stood on end because of a hungry look from a cat. Very well, Minsc will not crack open these cages, nor will he throw you out on your back seat.~
== WWSWOO ~I am glad to hear it.~
END
++ ~Hold on a moment. What is this place?~ EXTERN WWSWOO SwooPets
++ ~Where are we? Why is there no exit? How did we get here?~ EXTERN WWSWOO SwoosPetsExit

CHAIN
IF ~Global("WWFakeBoo","GLOBAL",1)~ THEN WWSWOO BooIsBackFake
~Here is your Boo, sir.~
== MINSCJ ~Oh joyous day! Boo is back to cuddle with Minsc! But wait-~
DO ~SetGlobal("WWFakeBoo","GLOBAL",2)~
= ~This... this is not looking like Boo. Why is his hair so grey? Why does he seek to flee off Minsc's hand?~
END
+ ~CheckStatGT([PC],14,CHR)~ + ~His hair is grey because he's been frightened to be without you, Minsc.~ EXTERN MINSCJ RunSo
+ ~CheckStatGT([PC],14,INT)~ + ~I believe it's Boo, Minsc. Are you doubting my intelligence?~ EXTERN MINSCJ RunSo
++ ~It -err- really is Boo, Minsc. Don't you trust me?~ EXTERN MINSCJ BetrayalBoo

CHAIN
IF ~~ THEN WWSWOO SwoosPetsExit
~No exit? Why, that's something I hadn't noticed before! Damned store-builders, forgot the door!~
= ~Heh, old Smethy's just joking with you. There is no door, bar a magical one. I hold the key to the exit and entrance, as does Billy, because he helps me plenty with this store. That's all you need know. As for the store itself...~
END
IF ~~ THEN EXTERN WWSWOO SwooPets

CHAIN
IF ~~ THEN WWSWOO SwooPets
~This place is Smethy's Prestige Pets, dedicated to finding an animal companion for everybody, from halfling to half-orc, from elf to dwarf, from human to well- another human, I guess.~
= ~I'm especially happy today to cater for such a fine ranger!~
== MINSCJ ~How did you know that Minsc is a ranger? You must be nearly as clever as Boo, or even <CHARNAME> here!~
== WWSWOO ~Simple deduction, my animal-loving friend. Now who is this Boo?~
== MINSCJ ~Boo- Boo is a giant heroic space hamster!~
== WWSWOO ~Gigantic? I must be getting old- can't see any hamster here, giant or otherwise.~
== MINSCJ ~No, Boo is a *travel-size* giant space hamster!~
== WWSWOO ~I.. see. And you are looking for a little friend for Boo, perhaps? A lovely young hamster lass, ready to mother a set of Boolets?~
== MINSCJ ~NO! Boo is NOT ready to be a father, although now that I think of it, Boolets would be very cute... But no! I am here because Boo is missing! And- and YOU have him! In fact, you are probably creating Boolets from Boo right now! Return him immediately!~
== WWSWOO ~You think I have your hamster? Now wait... Billy sold me a fine little hamster fellow not more than an hour ago.~
END
+ ~OR(6)
	Alignment(Player1,NEUTRAL_EVIL)
	Alignment(Player1,LAWFUL_EVIL)
	Alignment(Player1,CHAOTIC_EVIL)
	Alignment(Player1,NEUTRAL)
	Alignment(Player1,CHAOTIC_NEUTRAL)
	Alignment(Player1,LAWFUL_NEUTRAL)
	PartyGoldGT(199)~ + ~We'd like to buy Boo back from you, *whatever condition he might be in* (wink, wink). We're willing to offer you a pretty penny, as well.~ EXTERN WWSWOO PrettyPenny
+ ~OR(6)
	Alignment(Player1,NEUTRAL_EVIL)
	Alignment(Player1,LAWFUL_EVIL)
	Alignment(Player1,CHAOTIC_EVIL)
	Alignment(Player1,NEUTRAL)
	Alignment(Player1,CHAOTIC_NEUTRAL)
	Alignment(Player1,LAWFUL_NEUTRAL)
	PartyGoldGT(199)~ + ~We will buy Boo back from you, dear halfling. (*Any* hamster will suffice- as long as it looks like Boo, if you get my meaning.) 200 gold in it for you, my good halfling.~ EXTERN WWSWOO TakeIt
++ ~A fine hamster fellow? That could be Boo.~ EXTERN MINSCJ YesItsBoo
++ ~What do you think, Minsc? Could that be Boo?~ EXTERN MINSCJ YesItsBoo

CHAIN
IF ~Global("WWFakeBoo","GLOBAL",2)~ THEN MINSCJ RunSo
~Well, yeeeesssss, I suppose <CHARNAME> is right, but...~
DO ~SetGlobal("WWFakeBoo","GLOBAL",3)~
== AERIEJ IF ~IsValidForPartyDialog("Aerie")~ THEN ~No, that is not Boo! <CHARNAME>! Wh-why would you tell poor Minsc such a lie?!~
== NALIAJ IF ~IsValidForPartyDialog("Nalia")
			  !IsValidForPartyDialog("Aerie")~ THEN ~<CHARNAME>! This is a terrible thing to do! You shouldn't delude a friend like this! Minsc, that is *not* your hamster.~
== MAZZYJ IF ~IsValidForPartyDialog("Mazzy")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Nalia")~ THEN ~I'm not going to let you get away with such treachery, <CHARNAME>! I hope this is your idea of a joke, although your sense of humour is in very poor taste. Good Minsc, that is not your hamster. <CHARNAME>, for reasons I cannot understand, is lying to you.~
== MINSCJ IF ~OR(3) IsValidForPartyDialog("Aerie")
                    IsValidForPartyDialog("Nalia")
					IsValidForPartyDialog("Mazzy")~ THEN ~I do not believe that my great friend <CHARNAME> would lie to Minsc! But can <CHARNAME> explain why Boo is running so?~
END
+ ~OR(2) CheckStatGT([PC],14,CHR)
		    CheckStatGT([PC],13,INT)~ + ~He's still scared. He will calm down eventually.~ EXTERN MINSCJ SoBig
+ ~OR(2) CheckStatGT([PC],14,CHR)
		    CheckStatGT([PC],13,INT)~ + ~Perhaps he's missing his wheel, Minsc.~ EXTERN MINSCJ SoBig
++ ~He's probably just desperate to be running on the road again. I assure you, this *is* Boo.~ EXTERN MINSCJ TravelRoad


CHAIN
IF ~~ THEN MINSCJ YesItsBoo
~There is no finer hamster than Boo! But he did not tell you that he already belonged to Minsc? Why would he do such a thing?~
== KORGANJ IF ~IsValidForPartyDialogue("Korgan")~ THEN ~Well if it was a choice between spendin' yer days with an addled human and spendin' 'em with a hamster-lass, what would ye choose, ye blathering idiot? Wait, no, Korgan don't be wantin' an answer to that question. Not from *you*, anyway.~
== WWSWOO ~That was YOUR hamster? A ranger's animal companion, even! What a grand and noble creature! If I had known, I wouldn't have bought him off that Billy. Though he was a bargain, at one gold piece.~
== MINSCJ ~One gold piece? That is all Boo was worth to you?!~
== WWSWOO ~Actually, he ended up being worth 50 gold after I sold him.~
END
IF ~~ THEN EXTERN MINSCJ YouSoldBoo

CHAIN
IF ~~ THEN MINSCJ YouSoldBoo
~YOU SOLD BOO?! We... we will never catch little Boo! We are running in circles, <CHARNAME>. Minsc now understands the great cruelty that is the hamster wheel!~
= ~Oh, woe is me! Little Boo is lost to Minsc forever. Long will your hamster pawprints live in my memory, dear Boo!~
== WWSWOO ~Hold on a moment! Your hamster might not be so lost...~
= ~I'd not tell you this, except that I can see that hamster has a strong place in your heart and it pains me to see such good friends separated. I sold 'im to a young lass named Eleanya. She mentioned something about teaching him to swim.~
== MINSCJ ~Teach- teaching Boo to SWIM?!! This is.. this is worse than pirates. She must be an evil girl indeed, to want to teach him such things!~
END
++ ~Do you have any idea where Eleanya lives?~ EXTERN WWSWOO EllyLivesWhere
++ ~So where's this Eleanya brat? Out with it, halfling, unless you want me to tear it out of your throat!~ EXTERN WWSWOO EllyLivesWhereNasty


CHAIN
IF ~~ THEN MINSCJ NoCombat
~<CHARNAME> speaks sense, maybe. I am sorry to be doubting you so, Boo.~
== AERIEJ IF ~IsValidForPartyDialogue("Aerie")~ THEN ~So... it really *is* Boo? I.. I'm sorry, <CHARNAME>, for saying that you lied. I'm so happy, dear Minsc, that Boo is back.~
== NALIAJ IF ~IsValidForPartyDialog("Nalia")
			  !IsValidForPartyDialog("Aerie")~ THEN ~Could I have been wrong? But I suppose Minsc would know for sure if that was not Boo.~
== MAZZYJ IF ~IsValidForPartyDialog("Mazzy")
			!IsValidForPartyDialog("Aerie")
			!IsValidForPartyDialog("Nalia")~ THEN ~You were not lying after all, <CHARNAME>. I apologise for my earlier outburst. Perhaps it is the dim light that makes Boo look different to me. Let us carry on, goodfellow Minsc. I am glad that brave Boo has returned to us.~
== WWSWOO ~All dramas over? Good. I'll let you out, then. And remember, if you ever need an animal companion, Smethy's Prestige Pets is the place to go!~
= ~Erm, provided you can find it, of course.~
END
IF ~~ THEN      SOLVED_JOURNAL 	~Where oh where has my little Boo gone?

I have fooled Minsc into believing the a petstore hamster is his animal companion, Boo. With any luck, he will never realise that it is not his hamster. My party is now relieved of his hysterics and it is my hope that we will now travel in relative peace.~
				DO ~SetGlobal("WWBooGone","GLOBAL",3)
			   SetGlobalTimer("WWFakeBooTimer","GLOBAL",ONE_DAY)
				ActionOverride("Minsc",ChangeAIScript("wwbant",OVERRIDE))
			   	Wait(2)
				EraseJournalEntry(@2)
				EraseJournalEntry(@3)
				ClearAllActions()
				StartCutSceneMode()
				StartCutScene("WWGovt")~ EXIT


CHAIN
IF ~~ THEN MINSCJ NoRemorse
~You have been plotting this from the beginning?! Minsc was mistaken in thinking you were a hero! You are no hero! You are STINKING EVIL!~
= ~Rarrrghhh!! You reek with badness! Minsc will avenge Boo, yes! He will crush you into pellet-sized pieces! RARRRRRGHHHH!!!~
== EDWINJ IF ~IsValidForPartyDialogue("Edwin")~ THEN ~It was only a matter of time before these simians gave in to their baser instincts. Well, Edwin Odesseiron wil not scorn entertainment when it is offered (But watch the spittle, fools. This robe needs to be hand-washed.)~
END
IF ~IsValidForPartyDialogue("Aerie")~ THEN EXTERN AERIEJ AerieJoins
IF ~!IsValidForPartyDialogue("Aerie")~ THEN
	SOLVED_JOURNAL ~A Boo, the ranger, a Minsc and his hamster.

Minsc has discovered that pseudo-Boo is not in fact Boo. The outraged ranger turned on me and I was forced to slay him. My party will be the weaker for it and I would do well to refrain from such practical jokes in future.~
	DO ~SG("WWBooGone",5)
	ActionOverride("Minsc",LeaveParty())
      ActionOverride("Minsc",EquipMostDamagingMelee())
	ActionOverride("Minsc",Enemy())
	ActionOverride("Minsc",Attack(Player1))~ EXIT


CHAIN
IF ~~ THEN MINSCJ BetrayedMinsc
~Not... not the real Boo? I... I have been betrayed? By <CHARNAME>?~
== KORGANJ IF ~IsValidForPartyDialogue("Korgan")~ THEN ~Ah, don't look so surprised, ye great blathering fool.~
== NALIAJ IF ~!IsValidForPartyDialogue("Aerie")
			   IsValidForPartyDialogue("Nalia")~ THEN ~So it wasn't the same hamster after all. This is the type of behaviour I would expect of the servants, not you, <CHARNAME>!~
== MINSCJ ~Boo... little Boo... is still missing... I must find him! I must find him and tell him how sorry Minsc is, to have mistaken another hamster for him! There is only one Boo!~
END
IF ~IsValidForPartyDialogue("Aerie")
Global("MinscWitch","GLOBAL",1)
	!Global("AerieRomanceActive","GLOBAL",1)
	!Global("AerieRomanceActive","GLOBAL",2)~ EXTERN AERIEJ MinscNoRomance
IF ~IsValidForPartyDialogue("Aerie")
	OR(2)
		Global("AerieRomanceActive","GLOBAL",1)
        Global("AerieRomanceActive","GLOBAL",2)~ EXTERN AERIEJ MinscRomance
IF ~!IsValidForPartyDialogue("Aerie")~ EXTERN MINSCJ Leaving

CHAIN
IF ~~ THEN AERIEJ MinscNoRomance
~Minsc! W-we will go to find him right now! I- I am sorry to leave you like this, <CHARNAME>, but I.. I cannot travel with you any longer. Perhaps... perhaps we'll meet again.~
== MINSCJ ~Yes! We will find Boo, the REAL Boo, WITHOUT YOUR HELP! Beware the hamster teeth of justice, <CHARNAME>, for they WILL bite you one day!~
== MAZZYJ IF ~!IsValidForPartyDialogue("Aerie")
			  !IsValidForPartyDialogue("Nalia")
			   IsValidForPartyDialogue("Mazzy")~ THEN ~Well, I cannot blame him for leaving. You showed poor judgement in this matter, <CHARNAME>. I hope your plans for the rest of this group do not include more instances of such 'jokes'.~
END
IF ~IsValidForPartyDialogue("Edwin")~ THEN DO ~	SG("WWBooGone",5)
				ActionOverride("Minsc",LeaveParty())
				ActionOverride("Aerie",LeaveParty())
				ActionOverride("Minsc",GivePartyAllEquipment())
				ActionOverride("Aerie",GivePartyAllEquipment())
				ActionOverride("Minsc",EscapeArea())
				ActionOverride("Aerie",EscapeArea())~ EXTERN EDWINJ EdwinCommentAerie
IF ~!IsValidForPartyDialogue("Edwin")~ THEN
				SOLVED_JOURNAL ~An elf, the ranger, a Minsc and his hamster.

Minsc has discovered that pseudo-Boo is not in fact Boo. The outraged ranger has left my group and worse, has taken the cleric elf Aerie with him. My party will be the weaker for their loss and I would do well to refrain from such practical jokes in future.~
				DO ~SG("WWBooGone",5)
				ActionOverride("Minsc",LeaveParty())
				ActionOverride("Aerie",LeaveParty())
				ActionOverride("Minsc",GivePartyAllEquipment())
				ActionOverride("Aerie",GivePartyAllEquipment())
				ActionOverride("Minsc",EscapeArea())
				ActionOverride("Aerie",EscapeArea())~ EXIT

CHAIN
IF ~~ THEN MINSCJ Leaving
~Goodbye, <CHARNAME>. I.. I do not know what to think of you! You are as bad as a squirrel! No, worse! Minsc shall find Boo and we will together pelt copious nuts at <CHARNAME>'s head! So says Minsc!~
== KORGANJ IF ~IsValidForPartyDialogue("Korgan")~ THEN ~Hmph. An expensive joke, <CHARNAME>, when ye could've just squashed the little rat.~
END
IF ~IsValidForPartyDialogue("Edwin")~ THEN
				SOLVED_JOURNAL ~A Boo, the ranger, a Minsc and his hamster.

Minsc has discovered that pseudo-Boo is not in fact Boo. The outraged ranger has left my group to find his hamster and I doubt we will be able to find favour with him again. My party will be the weaker for their loss and I would do well to refrain from such practical jokes in future.~
				DO ~SG("WWBooGone",5)
				ActionOverride("Minsc",LeaveParty())
				ActionOverride("Minsc",GivePartyAllEquipment())
				ActionOverride("Minsc",EscapeArea())~ EXTERN EDWINJ EdwinComment
IF ~!IsValidForPartyDialogue("Edwin")~ THEN 								DO ~SG("WWBooGone",5)
				ActionOverride("Minsc",LeaveParty())
				ActionOverride("Minsc",GivePartyAllEquipment())
				ActionOverride("Minsc",EscapeArea())~ EXIT

CHAIN
IF WEIGHT #-43 ~Global("WWMinscFountain","LOCALS",2)~ THEN MINSCJ SeeElly
~She is the nasty girl the halfling was talking about?~
DO ~SetGlobal("WWMinscFountain","LOCALS",3)~
== MINSCJ IF ~IsValidForPartyDialogue("Edwin")
				Gender("Edwin",FEMALE)~ THEN ~She is pretty- maybe even prettier than Edwin's fair sister!~
== BEDWINWO IF ~IsValidForPartyDialogue("Edwin")
				Gender("Edwin",FEMALE)~ THEN ~(That- that cannot be! Am I... am I losing my looks? Invest in facial creams, Edwin, *immediately*.)~
== MINSCJ IF ~IsValidForPartyDialogue("Edwin")
				Gender("Edwin",FEMALE)~ THEN ~How can evil have so sweet a face?~
== MINSCJ IF ~OR(2)
				  !IsValidForPartyDialogue("Edwin")
				  Gender("Edwin",MALE)~ THEN ~She is pretty. How can evil have so sweet a face?~
== AERIEJ IF ~IsValidForPartyDialogue("Aerie")~ THEN ~I- I am no stranger to such illusions... but I don't think she is evil, Minsc.~
== MINSCJ ~Such a pretty lady could not be wholly evil, even if she is making Boo swim. I will approach her carefully, but in a friendly way.~
== HAERDAJ IF ~IsValidForPartyDialogue("Haerdalis")~ THEN ~And then you will pounce, my dear hound? The colour is in your cheeks- you need not hide your desire... let it free and reward yourself in her sweet caress.~
== KORGANJ IF ~IsValidForPartyDialogue("Korgan")~ THEN ~Friendly? Argh, ye longlimbs with yer fancy words in yer pursuit o' pleasure. A large stick and a strong back be all that's needed when wooin' a lass.~
== CERNDJ IF ~IsValidForPartyDialogue("Cernd")~ THEN ~Indeed, as the powerful leopard approaches his prey.~
== MINSCJ IF ~OR(3)
                  IsValidForPartyDialogue("Cernd")
				  IsValidForPartyDialogue("Korgan")
				  IsValidForPartyDialogue("Haerdalis")~ THEN ~What are you saying? Minsc only said that she is pretty!~
== EDWINJ IF ~OR(3)
                  IsValidForPartyDialogue("Cernd")
				  IsValidForPartyDialogue("Korgan")
				  IsValidForPartyDialogue("Haerdalis")
				IsValidForPartyDialogue("Edwin")~ THEN ~And lo, this idiot wastes a prime opportunity. I suppose it is a blessing in disguise that he is unskilled in the ways of seduction, lest the world become overrun with overbrawny monkeys.~
== VALYGARJ IF ~IsValidForPartyDialogue("Valygar")~ THEN ~She may be attractive, but Minsc, I counsel you to take care. I can sense the magic surrounding this woman even from where I stand.~
END
++ ~Subtlety is the key here. Let's find out what she's doing first.~ EXTERN MINSCJ Subtlety
++ ~I think we should just ask her for Boo. Perhaps you will appeal to her caring side.~ EXTERN MINSCJ AskHamster
++ ~Minsc, don't forget that this evil girl took your hamster from you. We will probably have to take Boo back by force.~ EXTERN MINSCJ AuraEvil

CHAIN
IF ~~ THEN MINSCJ AuraEvil
~You may be right, <CHARNAME>. But something about her reminds me of Dynaheir... I do not think she can be so evil.~
== WWELLE ~Go on, little hamster, swim! I did not use so much magic on you for nothing...~
== MINSCJ ~Or perhaps she IS evil after all! YOU THERE!~
== WWELLE ~Who me?~
== MINSCJ ~Yes, you! Step away from the fountain and place the hamster where I can see him, small lady!~
END
IF ~~ THEN EXTERN WWELLE WhatIsThis

CHAIN IF ~~ THEN MINSCJ AskHamster
~I will do so, <CHARNAME>. Boo would approve of being so upfront.~
= ~Excuse me, lady-~
== WWELLE ~Go on, little hamster, swim! I won't be picking you out this time... especially after using so much magic on you!~
== MINSCJ ~NO! STOP! Small lady, what do you think you are doing?!~
END
IF ~~ THEN EXTERN WWELLE WhatIsThis

CHAIN
IF ~~ THEN MINSCJ Subtlety
~Yes, Boo would approve of such sleuthing.~
= ~Excuse me, lady, but what are you doing with a hamster such as this?~
== WWELLE ~It's none of your business, man. Leave me to my work.~
= ~Now, little hamster, swim! I did not use so much magic on you for nothing...~
== MINSCJ ~NO! STOP! Small lady- what do you think you are doing?!~
END
IF ~~ THEN EXTERN WWELLE WhatIsThis


CHAIN
IF ~~ THEN WWELLE ToQuestions
~Good. Now my first question... I'll make it a riddle. All members of the De'Lyl family are well-versed in intelligent past-times. I would like to know if you are.~
== NALIAJ IF ~IsValidForPartyDialogue("Nalia")~ THEN ~'All members of the De'Lyl family are well-versed in intelligent past-times.' Lady De'Lyl, your arrogance is showing.~
== EDWINJ IF ~IsValidForPartyDialogue("Nalia")
			  IsValidForPartyDialogue("Edwin")~ THEN ~And what arrogance it is! Quieten down *Lady De'Arnise*, you inbred excuse for a milksop, and let the lady speak. (Yes, curry her favour, Edwin. Perhaps I will show her my brand of 'magic' later.)~
== WWELLE ~Listen carefully.~
= ~It goes along with the carriage,
It comes with the carriage,
The carriage has no need of it
Yet the carriage may not go without it.~
== MINSCJ IF ~IsValidForPartyDialogue("Minsc")~ THEN ~That is a hard one. Hmmm. Perhaps the answer is a horse, <CHARNAME>? (Come, Boo, whisper the answer to Minsc. No? Yes, I suppose cheating is for the wicked. How noble of you, Boo!)~
END
IF ~IsValidForPartyDialogue("Edwin")~ THEN EXTERN EDWINJ EdwinYawn
++ ~A horse.~  DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong1
++ ~A wheel.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong1
++ ~A driver.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE Wrong1
++ ~Noise.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE Right1
++ ~Seats.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong1
++ ~Passengers.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong1
++ ~A mephit named Noober.~ EXTERN WWELLE TotallyWrong
++ ~The carriage may not go without the most important thing? The answer is you, Lady De'Lyl.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE YouLady

CHAIN
IF ~~ THEN WWELLE TotallyWrong
~You are going to insist on being foolish? I will not waste my time this way! Good day to you!~
== MINSCJ ~You are not to leave until Boo is firmly in my hands, nasty lady!~
== WWELLE ~Stop calling me names... I warn you!~
== MINSCJ ~Return Boo NOW. I am warning YOU!~
== WWELLE ~(Sniff!) I wouldn't return him to a degenerate such as yourself, not for anything. Pootles likes me, so he is staying right here!~
== MINSCJ ~Pootles... Boo... for the crime of destroying Boo's good name, you must be punished! RARRRGHHHH!! FOR BOO!~
== WWELLE ~You dare attack me? You'll pay for attacking a De'Lyl, fool!~
END
IF ~~ THEN DO ~ClearAllActions()
               StartCutScene("wwctel")~ EXIT

CHAIN
IF ~~ THEN EDWINJ TellAnswer
~The answer is clearly 'noise'.~
== ANOMENJ IF ~IsValidForPartyDialogue("Anomen")
				Gender(Player1,MALE)~ THEN ~Nay, I have ridden in many a carriage in my life. The answer is a driver, <CHARNAME>.~
== ANOMENJ IF ~IsValidForPartyDialogue("Anomen")
				Gender(Player1,FEMALE)~ THEN ~Nay, I have ridden in many a carriage in my life. The answer is a driver, my lady.~
== WWELLE ~Well?~
END
++ ~The answer is 'noise'.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE Right1
++ ~A driver.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE Wrong1
++ ~A horse.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong1
++ ~A wheel.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong1
++ ~Seats.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong1
++ ~Passengers.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong1
++ ~A mephit named Noober.~ EXTERN WWELLE  TotallyWrong
++ ~You, Lady De'Lyl.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE  YouLady


CHAIN
IF ~~ THEN WWELLE Wrong1
~Well, you are not well-versed, although your guess is adequate. The answer was 'noise'. (Sniff) I answered that riddle correctly when I was but five years of age. You had better put away your adventuring boots and read some more.~
== EDWINJ IF ~IsValidForPartyDialogue("Edwin")~ THEN ~The answer was noise? Yess! Score one for the red wizard!~
END
IF ~~ THEN EXTERN WWELLE Question2

CHAIN
IF ~~ THEN WWELLE YouLady
~'The most important thing'... Haha! Well, you have a wit on you. I'll give you that one, although the actual answer is 'noise'.~
== EDWINJ IF ~IsValidForPartyDialogue("Edwin")~ THEN ~The answer was noise? Yess! Score one for the red wizard!~
END
IF ~~ THEN EXTERN WWELLE Question2

CHAIN
IF ~~ THEN WWELLE Right1
~'Noise' is correct. Hmm, perhaps I misjudged you.~
== EDWINJ IF ~IsValidForPartyDialogue("Edwin")~ THEN ~Yess! Score one for the red wizard!~
== WWELLE ~You are more intelligent than your appearance suggests. I will give you some advice <MANWOMAN>. Take a bath. The layer of dirt encrusted on your skin does you no favours.~
END
IF ~~ THEN EXTERN WWELLE Question2


CHAIN
IF ~~ THEN WWELLE Question2
~For my next question- another riddle.~
= ~I stand on one leg with my heart in my head. What am I?~
== EDWINJ IF ~IsValidForPartyDialogue("Edwin")~ THEN ~(Yawn.) Too simple a question.~
== MINSCJ ~Stands on one leg? Oh! I know this one! An eeeevil pirate! Tell me, is Minsc right?~
END
IF ~IsValidForPartyDialogue("Edwin")~ EXTERN EDWINJ NotSimpleEnough
++ ~A walking stick.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong2
++ ~A cabbage.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE  Right2
++ ~A key.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong2
++ ~A heron.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong2
++ ~A fireplace.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong2
++ ~A lover.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong2
++ ~A one-legged lover.. a pirate lover?~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE Wrong2
++ ~A spider missing 7 legs as well as having been born with a defective heart.~ EXTERN WWELLE TotallyWrong
+ ~Gender(Player1,MALE)~ + ~Me when I gaze upon your beauty.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE YouBeauty
+ ~Gender(Player1,FEMALE)~ + ~Any man, should he chance to come across your beauty.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE YouBeauty


CHAIN
IF ~~ THEN WWELLE Right2
~You are doing rather well.~
== EDWINJ IF ~IsValidForPartyDialogue("Edwin")~ THEN ~Yessss! Edwin Odesseiron, you are running red hot today! (Then again, when do I not?)~
END
IF ~~ THEN EXTERN WWELLE Question3

CHAIN
IF ~~ THEN WWELLE YouBeauty
~(Blush) I do believe I'm beginning to like you better, <CHARNAME>, was it? Your answer will suffice, though the true answer was, of course, a cabbage.~
== EDWINJ IF ~IsValidForPartyDialogue("Edwin")~ THEN ~Yessss! Edwin Odesseiron, you are running red hot today! (Then again, when do I not?)~
END
IF ~~ THEN EXTERN WWELLE Question3

CHAIN
IF ~~ THEN WWELLE Question3
~For my last question, I will deviate from the norm. Tonight I am attending a banquet at which I will be presented to many nobles. What stone should I wear with my dress?~
== EDWINJ IF ~IsValidForPartyDialogue("Edwin")~ THEN ~I think a ruby or a jargoon would be suitable. Red Tears if you like, or perhaps a garnet. Something to match my robe. (I will, after all, be your chosen partner for this gathering.)~
== MINSCJ ~Hmm, you are so pretty that you do not need a stone. But being a witch, you would look best with a Laeral's Tear. They were all the rage in Rashemen. But not in a beserking way, although that is the best kind of rage.~
== NALIAJ IF ~IsValidForPartyDialogue("Nalia")~ THEN ~A diamond would suit a person as flashy as yourself. Aunty tried to make me wear a string of them once. She wasn't impressed when I donated it to the poorhouse.~
== AERIEJ IF ~IsValidForPartyDialogue("Aerie")~ THEN ~I.. I like the idea of a pearl. White and gleaming... like.. like.. oh, never mind.~
== ANOMENJ IF ~IsValidForPartyDialogue("Anomen")~ THEN ~My lady, the dusky beauty of the rose ioun would set off the lustre of your skin remarkably. Aye, such a stone has even the power to protect the wearer from harm.~
== KORGANJ IF ~ OR(4)
					IsValidForPartyDialogue("Edwin")
                    IsValidForPartyDialogue("Nalia")
					IsValidForPartyDialogue("Aerie")
					IsValidForPartyDialogue("Anomen")
				IsValidForPartyDialogue("Korgan")~ THEN ~It's my misfortune to travel in a group with such simperin' idiots. Cannae ye see the pile of jewels fer the question? I say if she owns even half the stone ye mention, we kill her here and loot the body. Korgan be the only one ta see where there's gold ta be made.~
== WWELLE ~So, what stone should I wear?~
END
++ ~A red stone, such as the garnet.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE garnet
++ ~A colourless stone with hidden magic, such as the Laeral's tear.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE laeral
++ ~A sparkling stone, such as the diamond.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE diamond
++ ~A simple pearl.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE pearl
++ ~The rose ioun, to match your skin.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE ioun
++ ~A star sapphire to match your dress.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE sapphire
++ ~A green emerald to add fire to your eyes.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE emerald
+ ~IsValidForPartyDialog("Nalia")~ + ~Any stone would suit someone with your poise.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE anystoneNalia
+ ~!IsValidForPartyDialog("Nalia")~ + ~Any stone would suit someone with your poise.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE anystone
++ ~No stone is required to enhance your beauty, Lady De'Lyl.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE nostone

CHAIN
IF ~~ THEN WWELLE anystoneNalia
~How true you speak. I will perhaps wear all of them. Yes. It will demonstrate our wealth to all at the banquet.~
== NALIAJ IF ~IsValidForPartyDialogue("Nalia")~ THEN ~It will demonstrate your extreme lack of taste to all. Though I hardly suppose that you'd understand what 'taste' is.~
== WWELLE IF ~IsValidForPartyDialogue("Nalia")~ THEN ~Careful, dear Lady De'Arnise... your envy does not become you. Here, you may take the emerald for your coffers. It matches your complexion.~
END
IF ~~ THEN DO ~GiveItemCreate("MISC43","Nalia",0,0,0)  // Emerald
		~ GOTO Rewards

CHAIN
IF ~~ THEN WWELLE anystone
~How true you speak. I will perhaps wear all of them. Yes. It will demonstrate our wealth to all at the banquet.~
= ~I have no need for this little bag, then. Take it and keep your goods in it. Perhaps you will enjoy putting your little rocks and knick-knacks in it, hmm?~
END
IF ~~ THEN DO ~GiveItemCreate("BAG02",Player1,0,0,0)  // Gem bag
		~ GOTO Rewards

CHAIN
IF ~~ THEN WWELLE nostone
~Were your words any less sincere, I would think you were merely pandering to me. But you speak the truth. I do not need any of these stones to weigh me down. After all, there is such a thing as too much beauty.~
= ~Perhaps you would do me a favour and take them. Silly things, but I can always get more.~
== NALIAJ IF ~IsValidForPartyDialogue("Nalia")~ THEN ~Such a treasure would fill the stomachs of all the beggars in the city! When translated to coin, and then food, I mean.~
== KORGANJ IF ~IsValidForPartyDialogue("Korgan")~ THEN ~Heh. I think Korgan'll be payin' a little visit to the Delils soonish.~
== MINSCJ ~Have there been enough questions? Minsc thinks there have been enough questions.~
END
IF ~~ THEN DO ~ GiveItemCreate("MISC34",Player1,0,0,0)
				GiveItemCreate("HELM19",Player1,0,0,0)
				GiveItemCreate("AMUL12",Player1,0,0,0)
				GiveItemCreate("MISC36",Player1,0,0,0)
				GiveItemCreate("MISC43",Player1,0,0,0)
				GiveItemCreate("MISC42",Player1,0,0,0)
				GiveItemCreate("MISC41",Player1,0,0,0)~ GOTO Rewards


CHAIN
IF ~~ THEN WWELLE Compliment
~Goodbye.~
== NALIAJ IF ~IsValidForPartyDialogue("Nalia")~ THEN ~It is women like her who give an appalling name to nobles everywhere. <CHARNAME>, we are not all like that. I wish Aunty had been here to put her in her place.~
== EDWINJ IF ~IsValidForPartyDialogue("Edwin")~ THEN ~There goes a woman of substance. (Mental note #4,633: Must pay a visit De'Lyl estate once I have escaped the hairy clutches of these knuckling, slack-jawed imbeciles.)~
END
IF ~~ THEN DO ~ActionOverride("Minsc",ReallyForceSpellRES("wwboo",Myself))
				AddexperienceParty(20000)
				SetGlobal("WWBooGone","GLOBAL",2)
				ActionOverride("Minsc",ChangeAIScript("wwbant",OVERRIDE))
				ActionOverride("WWElle",EscapeArea())~ EXIT


CHAIN
IF ~~ THEN MINSCJ ThreatenElly
~Such rudeness will not be tolerated! Boo says that you must return him now, lest he bite your butt!~
== WWELLE ~Bite my WHAT?~
== MINSCJ ~You have heard him speak! Boo says that he has never seen evil so cheeky!~
END
IF ~~ THEN EXTERN WWELLE TotallyWrong



CHAIN
IF ~~ THEN WWELLE GreaterThings
~Your curiosity is a credit to you. Behold, what will be the first sea hamster in Faerun! That is, when my spell takes effect. He doesn't seem to like the water at present.~
== MINSCJ ~NO! Boo is a Space Hamster already! How can he be a sea hamster as well?!~
== WWELLE ~Your hamster... is a Space Hamster? Hmmm, that might be what is troubling my spell...~
END
++ ~Enough of this! Give us the hamster now, Eleanya. I do not want to use force, but I will if I have to.~ + NoWay
++ ~Your story confirms that you, Lady De'Lyl are the greatest idiot I will ever kill. Goodbye.~ + Inbred
++ ~Yes, you're very clever and ambitious. Could you give Boo back to us? You could easily buy another one. Here, I'll even give you the gold for it.~ + 1000Gold

CHAIN
IF ~~ THEN WWELLE InsultDelyl
~You're coming very close to wasting my time. The De'Lyls do NOT hunt mages. The De'Lyls do NOT travel on the road and become dustridden adventurers. We were made for better things.~
== NALIAJ IF ~IsValidForPartyDialogue("Nalia")~ THEN ~This one is an insult to nobles everywhere. How will the underclass ever change their opinions of us with people like her stomping about?~
== WWELLE ~So, do you agree, or do we battle to the death- YOUR death- this day?~
END
++ ~I agree to your terms. Begin the questions~ + ToQuestions
++ ~I'm not going to play your idiot games. You obviously don't want to give up the hamster, so we'll just take it off your dead body.~ + LifeFor


CHAIN
IF ~~ THEN WWELLE HamsterSwimLow
~You think I would tell you, a group of scruffy, overbearing louts? I would laugh, but I'm afraid to open my mouth too wide around you. I might catch something.~
== KORGANJ IF ~IsValidForPartyDialog("Korgan")~ THEN ~Like me fist, perhaps?~
== WWELLE ~Now, will you leave me in peace, or did you want a taste of my powers?~
== MINSCJ ~<CHARNAME>, I do not think she will give Boo back peacefully! What should we do?~
END
++ ~Well said, Minsc! This wench wants a fight, so we'll give her one!~ + Inbred
++ ~I tire of this prattle. Give me the hamster, or your life is forfeit.~ + LifeFor
+ ~PartyGoldGT(1000)~ + ~I have 1000 gold to spare... will you give me the hamster for that sum?~ + 1000Gold
++ ~Is there no way you will return the hamster to us? I do not wish to fight you for it.~ + NoWay


CHAIN
IF ~~ THEN WWELLE HamsterSwimHigh
~Hmm. You have the look of one who might appreciate what I'm trying to do here...~
= ~I will introduce myself first. My name is Eleanya De'Lyl.~
== NALIAJ IF ~IsValidForPartyDialogue("Nalia")~ THEN ~De'Lyl? It is a noble name, but I haven't heard of you before.~
== WWELLE IF ~IsValidForPartyDialogue("Nalia")~ THEN ~(Snort!) Of course not! My family does not mix with the common folk.~
== NALIAJ IF ~IsValidForPartyDialogue("Nalia")~ THEN ~Common folk? I am Nalia De'Arnise! If you have been in the city for any length of time, you *must* have heard of my family!~
== WWELLE IF ~IsValidForPartyDialogue("Nalia")~ THEN ~As I said, the De'Lyls do not mix with the common folk.~
== WWELLE ~As you may have gathered, I am rather talented in the art of magic. My abilities have caused quite a stir in my family, and though Father would have me learn to pluck an instrument instead, I will not stifle my talent to please him, or anyone else for that matter.~
= ~But do not think me rebellious or an ingrate. Out of respect for Father's wishes, I do not cast my spells within the boundaries of the land we possess.~
== VALYGARJ IF ~IsValidForPartyDialogue("Valygar")~ THEN ~So you came to Athkatla, the one city where magic is a criminal offence, instead. It makes me wonder what is it about this place that draws those least suited to its laws.~
== EDWINJ IF ~!IsValidForPartyDialogue("Valygar")
			  IsValidForPartyDialogue("Edwin")~ THEN ~Though you are not without your charms, the brain encased in that pretty head of yours is apparently of Minscian dimensions. What is the logic behind practising magic in a city that scorns its use? (Yes, it is well that my talents extend so far beyond the magical arts. The females of this city would undoubtedly agree.)~
== NALIAJ IF ~IsValidForPartyDialogue("Nalia")~ THEN ~I'm surprised you haven't run into trouble with the Cowled Wizards. Or do the De'Lyls receive special treatment based upon their standing? My family wouldn't dream of abusing our position in such a way.~
== WWELLE ~Athkatla is the perfect place for me to refine my magic. There are no mages here to couch off my talents and the Cowled Wizards (pish!) know not to interfere with Eleanya De'Lyl.~
== MINSCJ ~But what of Boo, lady? What has he to do with your witching?~
== WWELLE ~Witching? Such a quaint term... But I suppose I can hardly expect *you* to comprehend the arcane.~
= ~As for 'Boo', I scryed the location of a magical store where he caught my eye. So ordinary, so plain, yet destined for greater things!~
== MINSCJ ~Boo- you think Boo is ordinary? Do you not see the smart way he scratches behind his ear?~
END
++ ~I'm almost afraid to ask, but what greater things are you speaking of?~ + GreaterThings
++ ~I tire of this story. Give me the hamster, or your life is forfeit.~ + LifeFor
+ ~PartyGoldGT(1000)~ + ~I have 1000 gold to spare... will you give me the hamster for that sum?~ + 1000Gold
++ ~Great. Another inbred mage, trapped in her delusions of granduer. Should I just kill you now or do you insist on babbling out the rest of your story?~ + Inbred

CHAIN
IF ~~ THEN WWELLE UnhandHamster
~This hamster is MINE. I've invested alot of time in him and you're not about to take him away!~
== MINSCJ ~But- but that is Minsc's Boo! Boo belongs with nobody else but Minsc!~
== WWELLE ~You're making not a mite of sense, man. What is this 'boo' you speak of?~
== MINSCJ ~Boo is the hamster you are holding! He is Minsc's best and dearest friend. Oh please, give Boo back to me! Minsc misses him so!~
END
IF ~~ THEN EXTERN WWELLE Yours


CHAIN
IF WEIGHT #-42 ~Global("WWBooVictory","LOCALS",1)~ THEN MINSCJ BooIsBack
~Is- is this to be believed? Has Minsc regained his Boo? Little Boo says it is so, so it must be true. Oh Boo, I have missed you!~
DO ~SetGlobal("WWBooVictory","LOCALS",9)~
= ~My lungs once again are filled with joy! The spring is back in my step! I am so hearty that I will soon be beating everybody up, although Boo says that is not a good way to make friends.~
= ~What- what was that, Boo? A great hamster battle cry is coming, cover your ears, <CHARNAME>, Boo is feeling the urge to bellow!~
= ~Boo says, WOE TO YOU, EVIL!! HEROES AND HAMSTERS ARE REUNITED!~ [gam_48]
= ~Boo, that was a battle cry to shake the shoes of villains everywhere! You may just have heard a squeak <CHARNAME>, but I assure you that it was terrifying. May we never be parted again, dear Boo!~
END
IF ~~ THEN SOLVED_JOURNAL ~Of hamsters and heroes.

Oh joyous day! Boo has been returned to Minsc and our ranger friend is back to normal, and stronger for his ordeal. I do not think that Boo will be let out of Minsc's sight, or pack, anytime soon.~
			DO ~EraseJournalEntry(@2)
	        EraseJournalEntry(@3)
	        EraseJournalEntry(@0)
		  	EraseJournalEntry(@1)
	        SetGlobal("WWCowledAppearance","GLOBAL",1)~ EXIT

CHAIN
IF WEIGHT #-2 ~Global("WWAttackedElly","GLOBAL",2)~ THEN WWELLE NotWorth
~Halt! There has been enough death today. Is the price of one hamster worth four lives?~
DO ~SG("WWAttackedElly",3)~
= ~Here, take it back if you desire it so. May the De'Lyl blood on your hands haunt you to the end of your days.~
END
IF ~~ THEN DO ~	ActionOverride("Minsc",ReallyForceSpellRES("wwBoo",Myself))
				SetGlobal("WWBooGone","GLOBAL",2)
				EscapeArea()~ EXIT


CHAIN
IF WEIGHT #-41 ~Global("WWBooVictory","LOCALS",2)~ THEN MINSCJ BooBackSombre
~Oh Boo, I have missed you so! <CHARNAME> and Minsc have done many things in your absence, some things not so heroic.~
DO ~SetGlobal("WWBooVictory","LOCALS",9)~
= ~I will cover your little eyes, Boo, until we are away from this place. Minsc is sorry that these men had to die for you to be safe in his arms once again.~
= ~What is it that Boo says? He says 'thank you' to <CHARNAME>. You lift the weight off my heart, Boo, when you talk in such a way. Let us never be parted again! Come, <CHARNAME>, let us go and find some evil to kick. Minsc and Boo are ready once again!~
END
IF ~~ THEN  SOLVED_JOURNAL ~Of hamsters and heroes.

After a battle with an overbearing noble and her guards, Boo has been returned to Minsc. Our ranger friend is back to normal, and stronger for his ordeal. I do not think that Boo will be let out of Minsc's sight, or pack, anytime soon.~
			DO 	~EraseJournalEntry(@2)
	        EraseJournalEntry(@3)
	        EraseJournalEntry(@0)
		  	EraseJournalEntry(@1)
			SetGlobal("WWCowledAppearance","GLOBAL",1)~ EXIT


CHAIN
IF ~~ THEN WWELLE hitMinsc
~Completely intentional (ahem). I... decided that it would not be worth creating a sea hamster if he was only to be gifted to you. Yes. Therefore I cast an alternative spell- quite deliberately, I assure you. But this spell will undoubtedly come in handy for your big friend here.~
= ~If he should lose his hamster in future, he will find that he has the ability to create a new one for himself.~
== MINSCJ ~There is no hamster that may replace Boo except Boo himself!~
== WWELLE ~Yes, yes. Although you might find this one a tad more useful than the little chubby one there. How much are you feeding him anyway?~
== MINSCJ ~Boo says not enough! But that is what Boo always says.~
= ~But now to think of a name for a second Boo. Boo-two? Booboo? Boo deaux?~
== WWELLE ~I'll leave you to this intellectual pursuit. As for me, I must scry out that pet store once again. I do hope I have time before the banquet begins. Farewell!~
END
IF ~~ THEN DO ~ ActionOverride("Minsc",ReallyForceSpellRES("wwboo",Myself))
				AddexperienceParty(20000)
				SetGlobal("WWBooGone","GLOBAL",2)
				ActionOverride("Minsc",ChangeAIScript("wwbant",OVERRIDE))
				ActionOverride("Minsc",AddSpecialAbility("wwblet"))
				EscapeArea()~ EXIT


/////////////////////
/* APPENDs go here */
/////////////////////


/* Minsc */

APPEND ~MINSCJ~

IF WEIGHT #-50 ~Global("WWBooGone","GLOBAL",1)
	Global("WWMinscHorror","LOCALS",1)
	~ THEN BEGIN BooIsMissing
SAY ~Ahh, this is a fine place for an adventure, isn't it, Boo? So many holes for a hamster to snuffle in, especially a miniature one such as yourself!~ [Error01]
= ~Boo?~
= ~Boo? Where are you?~
= ~Oh! Boo is playing a joke on Minsc! He is hiding in Minsc's backpack!~
= ~Boo?~
= ~BOO?! You are not there!! Where has Boo gone?!~
++ ~Perhaps Boo got tired of living in your backpack and ran away. Have you ever considered cleaning it?~ DO ~SetGlobal("WWMinscHorror","LOCALS",2)~ + BooRun
++ ~Look harder. Boo's probably sleeping in your armour somewhere.~ DO ~SetGlobal("WWMinscHorror","LOCALS",2)~ + BooArmour
++ ~Some cat probably ate him. Good riddance I say.~ DO ~SetGlobal("WWMinscHorror","LOCALS",2)~  + CatGotYourBoo
++ ~Uh-oh, looks like somebody's taken Boo. Whoever it is had better fess up!~ DO ~SetGlobal("WWMinscHorror","LOCALS",2)~  + AccuseStealBoo
END

IF WEIGHT #-49 ~Global("WWBooGone","GLOBAL",1)
Global("WWHelpFindBoo","GLOBAL",3)
	Global("WWBooComplaint","LOCALS",0)~ THEN BEGIN BooStillMissing
SAY ~<CHARNAME>! Did I not say that we should look in the Docks? You said that you would help me look for little Boo! I see no helping!~
++ ~Not to worry, Minsc. It's all part of the plan. We will sneak up on evil on silent feet!~ DO ~SetGlobal("WWBooComplaint","LOCALS",1)~ + Hmmm
++ ~We ARE looking for him, Boo.~ DO ~SetGlobal("WWBooComplaint","LOCALS",1)~ + Looking
++ ~Shut up about that hairball, wouldya?~ DO ~SetGlobal("WWHelpFindBoo","GLOBAL",10)~ + Mad        // This shuts up the complaints
END

IF WEIGHT #-48 ~Global("WWBooGone","GLOBAL",1)
	Global("WWHelpFindBoo","GLOBAL",5)
	Global("WWBooComplaint2","LOCALS",0)~ THEN BEGIN BooStillMissing2
SAY ~<CHARNAME>!! We still have not looked under every fish in the Docks!! We must go there straight away!~
= ~Boo could be in the hands of an evil pirate as we speak!! You said before that we would find him, but my pocket is still cold from lack of Boo!!~
++ ~We'll head there right away.~ DO ~SetGlobal("WWBooComplaint2","LOCALS",1)~ + Hmmm2
++ ~We've just been unlucky so far. Hold on abit longer.~ DO ~SetGlobal("WWBooComplaint2","LOCALS",1)~ + Looking2
++ ~Shut your trap. We're not going to look for him.~ DO ~SetGlobal("WWHelpFindBoo","GLOBAL",10)~ + Mad        // This shuts up the complaints
END

IF WEIGHT #-47 ~Global("WWBooGone","GLOBAL",1)
	Global("WWHelpFindBoo","GLOBAL",7)
	Global("WWBooComplaint3","LOCALS",0)~ THEN BEGIN BooStillMissing3
SAY ~You are no friend <CHARNAME>! You waft of stinking non-hamster-finding evil! Let it be known that once I have found little Boo, we will come and kick your butt liberally and then dose you with the perfume of goodness!!~
IF ~~ THEN	SOLVED_JOURNAL ~Where oh where has my little Boo gone?

We have delayed too long in our search for Minsc's hamster Boo, and our ranger friend has left us, vowing to find Boo on his own. It is my hope that we will come across Minsc once again in our travels- hopefully reunited with his Boo.~
			DO ~SetGlobal("WWBooComplaint3","LOCALS",1)
			ActionOverride("Minsc",LeaveParty())
			SG("WWBooGone",4)
			LeaveParty()
			GivePartyAllEquipment()
			EscapeArea()
			EraseJournalEntry(@2)
	        EraseJournalEntry(@3)
	       	EraseJournalEntry(@0)
		  	EraseJournalEntry(@1)~ EXIT
END

IF WEIGHT #-46 ~Global("WWMinscFountain","LOCALS",1)
				Global("WWFountain","LOCALS",0)~ THEN BEGIN BooFountain
SAY ~We must make haste and check every fountain, <CHARNAME>. Boo is in peril! Or underwater. Either is bad.~
IF ~~ THEN DO ~SetGlobal("WWFountain","LOCALS",1)~ EXIT
END

IF ~See("WWBill")
	Global("WWBooGone","GLOBAL",1)
	Global("WWBillySeen","GLOBAL",1)~ THEN YouBilly
SAY ~You! Minsc remembers you! You were looking at Boo, little boy! You know!!~
IF ~~ THEN DO ~ClearAllActions()
				SetInterrupt(FALSE)
				SetGlobal("WWBillySeen","GLOBAL",2)
				SetGlobal("WWHelpFindBoo","GLOBAL",10)
				DisplayStringHead("WWBill",5251)
				ActionOverride("WWBill",Wait(1))
				ActionOverride("WWBill",MoveToPointNoInterrupt(\[2270.2104\]))
				ActionOverride("WWBill",OpenDoor("Door0314"))
				SetInterrupt(FALSE)
				ActionOverride("WWBill",SmallWait(3))
				ActionOverride("WWBill",MoveBetweenAreas("AR0314",\[412.542\],2))~ EXIT
END

IF WEIGHT #-45 ~Global("WWFakeBoo","GLOBAL",1)
				GlobalTimerExpired("WWFakeBooTimer","GLOBAL")~ THEN FakeBooComment1
SAY ~Ah, Boo, it is good to have you back. Indeed, with the weight you have gained, there is more of you back than ever!~
+ ~GLT("Chapter",5)~ + ~Are you quite finished with Boo? We have a task to do, and your distractions are slowing down the group.~ DO ~SetGlobal("WWFakeBoo","GLOBAL",2)~ + MeanChar
+ ~!GLT("Chapter",5)~ + ~Are you quite finished with Boo? We have a task to do, and your distractions are slowing down the group.~ DO ~SetGlobal("WWFakeBoo","GLOBAL",2)~ + MeanChar6
++ ~Minsc, I... have a confession to make.~ DO ~SetGlobal("WWFakeBoo","GLOBAL",2)~ + Confession
END

IF WEIGHT #-44 ~Global("WWBooLie","LOCALS",2)
				GlobalTimerExpired("WWFakeBooTimer","GLOBAL")~ THEN FakeBoo2
SAY ~Good morning, Boo! Good morning, Boolets!~
= ~Wait- why is Boo having Boolets? Boo, is there something you have not told me?!~
= ~No, Boo is a boy. Many times he has told me this! Which means... which means that.. This is not Boo!!~
= ~<CHARNAME>, you told me this was Boo! You betrayed Minsc? Your most loyal friend? Why?~
++ ~Just for the look that's on your face right now.~ DO ~SetGlobal("WWBooLie","LOCALS",3)~ + NoRemorse
++ ~What can I say? I was bored.~ DO ~SetGlobal("WWBooLie","LOCALS",3)~  + NoRemorse
++ ~I was sick of your frequent bellowing and rampant imbecility. Getting rid of your hamster was the first step to getting rid of YOU.~ DO ~SetGlobal("WWBooLie","LOCALS",3)~  + NoRemorse
++ ~Enough of these foolish jokes! I've often wondered how I would fare in battle against you. Draw arms, Minsc! Let's see how well you do WITHOUT Boo!~ DO ~SetGlobal("WWBooLie","LOCALS",3)~  + NoRemorse
++ ~It was a joke.. gone wrong. I bought an ordinary hamster from Smethy. For what it's worth, I'm sorry, Minsc.~ DO ~SetGlobal("WWBooLie","LOCALS",3)~  + BetrayedMinsc
END

IF ~Global("WWMinscLeavesDying","LOCALS",1)~ THEN MinscLeavesDyingTalk
SAY ~NO! This cannot be! Minsc will not perish without his Boo!~
IF ~~ THEN  SOLVED_JOURNAL ~Where oh where has my little Boo gone?

Minsc has left my party after looking death in the eye once too often. It appears that the loss of Boo has diminished his courage as well as his strength. I doubt we will see him again and it is my hope that in time he will find Boo.~
			DO ~GivePartyAllEquipment()
				EraseJournalEntry(@2)
	        	EraseJournalEntry(@3)
	        	EraseJournalEntry(@0)
			  	EraseJournalEntry(@1)
			EscapeArea()~ EXIT
END

IF ~Global("WWMinscInBrynnlaw","LOCALS",1)
	G("WWBooGone",1)
	G("Chapter",4)
	AreaCheck("AR1600")~ THEN MinscMadInBrynnlaw
SAY ~Why... why did you take me here to this piratey place? Boo surely cannot have travelled over wind and wave.~
++ ~I know in my heart of hearts that Boo is here. Trust me in this.~ + TrustMe
++ ~Well, you're here now and there's no way back. Forget about Boo, as you should have, a long time ago.~ + ForgetBoo
++ ~Boo? What are you talking about, man?~ + Addled
++ ~Shut your mouth lest I shut it for you. Forget ye hamster and let's we be singin a sea shanty or two... Arrr, the sea air does me good!~ + ForgetBoo
END

IF ~~ TrustMe
SAY ~NO! I have trusted <CHARNAME>'s word for too long and Boo is not yet back! This.. this leaves me no choice but to go and search for him myself. Minsc will SWIM the many leagues back to Athkatla for Boo!~
= ~Hmmm, carrying so much, Minsc will surely sink. Take my sword, <CHARNAME>, will you? Oh, take everything! Minsc will go searching in only his pants and shirt and perhaps carrying something buoyant. Such is my dedication to Boo!~
IF ~~ THEN SOLVED_JOURNAL ~Where oh where has my little Boo gone?

We have delayed too long in our search for Minsc's hamster Boo, and our ranger friend has left us, vowing to find Boo on his own. It is my hope that we will come across Minsc once again in our travels- hopefully reunited with his Boo.~
				DO ~SG("WWBooGone",4)
				EraseJournalEntry(@2)
	     	   	EraseJournalEntry(@3)
	        	EraseJournalEntry(@0)
		  		EraseJournalEntry(@1)
				LeaveParty()
				GivePartyAllEquipment()
				EscapeArea()~ EXIT
END

IF ~~ ForgetBoo
SAY ~Forget Boo?! I think the sea air has done you no good and your brain has become oversalted! You.. you have become evil <CHARNAME>! I did not know salt could do such things to you! It is a woeful side effect, indeed!~
= ~Minsc will pound in your skull and remove the salt for you! For Boo as well!~
IF ~~ THEN SOLVED_JOURNAL ~Where oh where has my little Boo gone?

Minsc began attacking me when we arrived in Brynnlaw! Perhaps my harsh words about his hamster were too much for the large man to take. At any rate, I have slain him, and unless the tales about pirate ghosts be true, he shall not bother me again.~
				DO ~EraseJournalEntry(@2)
		        EraseJournalEntry(@3)
	    	    EraseJournalEntry(@0)
		  		EraseJournalEntry(@1)
				LeaveParty()
				Enemy()
				Attack(Player1)~ EXIT
END

IF ~~ Addled
SAY ~What am I talking about? <CHARNAME>, you have forgotten? I am talking about my missing hamster. He is about yea big and answers to the name of Boo.~
= ~He enjoys crackers and long walks in his treadmill...~
= ~Oh. <CHARNAME> was joking. Very funny joke, although Minsc will not be laughing UNTIL HE GETS BOO BACK!!~
++ ~I know in my heart of hearts that Boo is here. Trust me in this.~ + TrustMe
++ ~Face the facts, Minsc and forget about Boo. He's gone. I made sure of that- there's an ocean between you now.~ + ForgetBoo
++ ~Shut your mouth lest I shut it for you. Forget ye hamster and let's we be singin a sea shanty or two... Arrr, the sea air does me good!~ + ForgetBoo
END


IF ~~ MeanChar
SAY ~Do not listen to <CHARNAME>, little Boo. <PRO_HESHE> is just grumpy because <PRO_HESHE> is missing sweet Imoen. I was quite angry, too, when you were missing.~
IF ~~ THEN DO ~SetGlobalTimer("WWFakeBooTimer","GLOBAL",ONE_DAY)
			   SetGlobal("WWBooLie","LOCALS",1)~ EXIT
END

IF ~~ MeanChar6
SAY ~Do not listen to <CHARNAME>, little Boo. <PRO_HESHE> is just grumpy. Though it would be best if you would not eat your crackers on <PRO_HISHER> bedroll again.~
IF ~~ THEN DO ~SetGlobalTimer("WWFakeBooTimer","GLOBAL",ONE_DAY)
			   SetGlobal("WWBooLie","LOCALS",1)~ EXIT
END

IF ~~ Confession
SAY ~Minsc and Boo will listen to your confession. I hope it is not too evil a deed. Speak slowly so that I may cover Boo's ears if it is needed.~
++ ~Oh, never mind.~ + WeirdCharname
++ ~That.. that's not the real Boo. I tricked you before and I'm sorry for it.~ + BetrayedMinsc
++ ~That's not the real Boo! I sure pulled one over your eyes! Haha! You should see your face right now!~ + NoRemorse1
END

IF ~~ NoRemorse1
SAY ~Not... Not the real Boo? You have tricked Minsc? And you LAUGH so wickedly about it?~
= ~This is beyond bad! This makes the evilness of the red wizard look pink in comparison! And you...~
IF ~~ THEN EXTERN MINSCJ NoRemorse
END

IF ~~ WeirdCharname
SAY ~<CHARNAME>, you act so odd. But I suppose it is because you are so joyful at Boo's return, yes?~
IF ~~ THEN DO ~SetGlobalTimer("WWFakeBooTimer","GLOBAL",ONE_DAY)
			   SetGlobal("WWBooLie","LOCALS",1)~ EXIT
END

IF ~~ Hmmm
SAY ~Minsc... is sorry to be doubting you so. I am just suffering a nervous rash to think of Boo without his Minsc and it is getting quite chafey in this armour. Let us keep on looking.~
IF ~~ THEN EXIT
END

IF ~~ Mad
SAY ~I was mistaken about you <CHARNAME>!! You are no hero! You leave small hamsters lost in large cities!~
= ~Tell me truthfully, did you ever intend to reunite Minsc and Boo?~
++ ~Of course I did, Minsc. You may trust your greatest friend's word.~ + TrustMeInThis
++ ~Perhaps eventually. My quest is more important, though you may not realise this.~ + QuestOwn
++ ~Truth is, I never liked that hamster in the first place.~ + MinscAttackYou
END

IF ~~ TrustMeInThis
SAY ~You... you lie! We have been walking about for days and yet we have not found him! A smart friend such as you should have sniffed him out by now, but perhaps you are not a friend at all!~
= ~Minsc is disappointed in you, <CHARNAME>. We are friends no longer.~
IF ~~ THEN GOTO MinscLeavesGone
END

IF ~~ MinscLeavesGone
SAY ~I will go and find Boo myself. Perhaps we may meet again and Boo might forgive you even if I will not. But I will listen to Boo's wise words at such a time.... if there IS such a time.~
IF ~~ THEN 		SOLVED_JOURNAL ~Where oh where has my little Boo gone?

We have delayed too long in our search for Minsc's hamster Boo, and our ranger friend has left us, vowing to find Boo on his own. It is my hope that we will come across Minsc once again in our travels- hopefully reunited with his Boo.~
				DO ~EraseJournalEntry(@3)
			    EraseJournalEntry(@2)
	 	     	EraseJournalEntry(@0)
		  	    EraseJournalEntry(@1)
			    SG("WWBooGone",4)
			    LeaveParty()
			    GivePartyAllEquipment()
				EscapeArea()~ EXIT
END

IF ~~ QuestOwn
SAY ~And.. and you did not tell Minsc this? You deceived him so willingly? What would Boo say about such behaviour?~
= ~He would say.. he would say... WHAT??! And then he would ask for a cracker, but Boo is prone to such greediness sometimes.~
= ~Oh, Minsc is disappointed in <CHARNAME>! Betrayed by his only friend in the world besides Boo... but you are no longer a friend!~
IF ~~ THEN GOTO MinscLeavesGone
END

IF ~~ MinscAttackYou
SAY ~You.. you never liked Boo?! Is that why you would leave Boo in the hands of stinking evil? To have ale poured on his fur and to suffer the shanties? You-~
= ~You are evil most heinous... You have betrayed Minsc... You have betrayed BOO!!~
= ~Such evil must be destroyed! MINSC will destroy such evil! In Boo's name!~
= ~RrrRRRAARRGGGHHHHHHHHHHH!!! For hamsters everywhere!!~
IF ~~ THEN 		SOLVED_JOURNAL ~Where oh where has my little Boo gone?

I was forced to slay Minsc today after he went beserk over my refusal to look for his missing hamster, Boo. My party is weaker for it, and I must look for an adequate replacement.~
				DO ~EraseJournalEntry(@3)
			    	EraseJournalEntry(@2)
	 	     	    EraseJournalEntry(@0)
		  	    	EraseJournalEntry(@1)
				EquipMostDamagingMelee()
				LeaveParty()
				Enemy()
				Attack(Player1)~ EXIT
END


IF ~~ Hmmm2
SAY ~I am warning you, <CHARNAME>! From this point onwards, when I am not searching for Boo, I will be watching your backside!~
IF ~~ THEN UNSOLVED_JOURNAL ~Where oh where has my little Boo gone?

Minsc is becoming more upset by the minute as we have not yet found his hamster. I fear that he will leave the party and seek Boo on his own should we tarry much longer. Minsc mentioned that he last saw Boo near sailors and pirates. Perhaps we should investigate the Sea's Bounty Tavern in the Docks district.~

		DO ~RealSetGlobalTimer("WWFindBooTimer","GLOBAL",300)
			IncrementGlobal("WWHelpFindBoo","GLOBAL",1)~ EXIT
END


IF ~~ BooRun
SAY ~No!! Boo would not run away from Minsc, no matter how badly his backpack might smell! Besides, Minsc's backpack only smells of Boo's cheese, which he does not mind. No, Boo was stolen!!~
IF ~~ THEN GOTO AccuseStealBoo
END

IF ~~ BooArmour
SAY ~No!! Minsc has checked his armour thoroughly, from front to back and down and up! No, Boo was stolen!!~
IF ~~ THEN GOTO AccuseStealBoo
END

IF ~~ CatGotYourBoo
SAY ~You would.. you would wish such a thing on little Boo! Could it be that <CHARNAME> has an evil butt and Minsc never noticed? This will remind me to look more closely at my fellow traveller's behinds in future!~
= ~I will travel with you no longer, <CHARNAME>! Minsc will find Boo ALL BY HIMSELF!~
IF ~~ THEN DO ~	SG("WWBooGone",4)
				LeaveParty()
				GivePartyAllEquipment()
				EscapeArea()~ EXIT
END

IF ~~ BooKidding
SAY ~Minsc *never* jokes about Boo! Weasels, maybe! Boo, NEVER!~
++ ~Calm down, Minsc. We'll help you find your Boo.~ + HelpFindBoo
++ ~I am sure you don't. We should get going at any rate. You've distracted this group long enough.~ + NotHelpBoo
END

IF ~~ BooLaughter
SAY ~Oh, tragedy is me! Overcome by the treachery of my most faithful friend! Tales shall be told of this dark day in years to come! Plays shall be made of it, acted in badly and I shall turn over in my grave at the horror!~
++ ~Calm down, Minsc. We'll help you find your Boo.~ + HelpFindBoo
++ ~If you can stop your hysterics, we should get going. You've distracted this group long enough.~ + NotHelpBoo
END

IF ~~ NotHelpBoo
SAY ~Yes! We must go to find Boo now! We will leave no stone in this city unturned, no hamster hole untouched, right Boo?~
= ~(sniff) Minsc means- right, <CHARNAME>?~
++ ~Who says I'm going off to find your rodent? We have more important things to do right now.~ + SadMinsc
++ ~Yes Minsc, let's go find Boo.~ + HelpFindBoo
++ ~Not right now, Minsc. We have a more important and more noble task right now. We must find Imoen.~ + SadMinsc
END

IF ~~ HelpFindBoo
SAY ~You will help Minsc find his Boo? Oh you are a true friend to join me on this most noble quest! We are such heroes, to be rescuing hamsters in distress, are we not?~
++ ~Do you have any idea where he might be?~ + ToTheDocks
++ ~Yes, we are great heroes, Minsc! But where should we start?~ + ToTheDocks
END

IF ~~ SadMinsc
SAY ~You... you will not help Minsc find his Boo? You would allow great heroes to be kept apart? I do not believe it is so!~
++ ~Oh all right, Minsc, we'll go look for your blasted hamster.~ + HelpFindBoo
++ ~Sorry, Minsc. You'll have to look for him on your own.~ + SadMinsc2
END

IF ~~ SadMinsc2
SAY ~Minsc will find Boo WITHOUT <CHARNAME>'s help! Minsc is hero enough to find Boo all by himself! Hold your whiskers steady Boo, Minsc will beat a valiant path to your paws!~
IF ~~ THEN SOLVED_JOURNAL ~Where oh where has my little Boo gone?

Minsc has left my party in anger after I told him that we must part. The ranger did not understand how I could leave him while his hamster was still missing and has stormed off, vowing to look for Boo. I do not think we will see his like again.~
				DO ~SG("WWBooGone",4)
			    EraseJournalEntry(@3)
			    EraseJournalEntry(@2)
	 	     	EraseJournalEntry(@0)
		  	    EraseJournalEntry(@1)
				SetGlobal("WWHelpFindBoo","GLOBAL",10)
			 	LeaveParty()
				GivePartyAllEquipment()
				EscapeArea() ~ EXIT
END

IF ~~ ToTheDocks
SAY ~I last saw little Boo near all those sailors and pirates in the docks. He will be so scared without his great ranger friend to protect him! We must head there with no delay!~
= ~Minsc... (sniff)... Minsc misses his little Boo.~
IF ~~ THEN UNSOLVED_JOURNAL ~Where oh where has my little Boo gone?

A most tragic event has occurred! Minsc has discovered that his pet hamster Boo is missing and the large ranger is distraught. I have promised him that we will search the Docks district for clues to his disappearance, as this is where Minsc last remembers seeing him.~
			DO ~SetGlobal("WWHelpFindBoo","GLOBAL",1)~ EXIT
END

IF ~~ Looking
SAY ~Less looking! More finding! So say Minsc and... Minsc!!~
IF ~~ THEN EXIT
END

IF ~~ Looking2
SAY ~How much longer? A dreadful pirate might be forcing Boo to drink ale as we speak! You and I know that Boo is too young for such things! To the Docks, NOW, <CHARNAME>, lest my boot meet your butt!~
IF ~~ THEN UNSOLVED_JOURNAL ~Where oh where has my little Boo gone?

Minsc is becoming more upset by the minute as we have not yet found his hamster. I fear that he will leave the party and seek Boo on his own should we tarry much longer. Minsc mentioned that he last saw Boo near sailors and pirates. Perhaps we should investigate the Sea's Bounty Tavern in the Docks district.~
			DO ~RealSetGlobalTimer("WWFindBooTimer","GLOBAL",300)
			IncrementGlobal("WWHelpFindBoo","GLOBAL",1)~ EXIT
END

IF ~~ MinscReconsiders
SAY ~BUTTKICKING-~
= ~Wait!! This is not the way to find little Boo! Even if I cut down these bad men, little Boo will still be quite lost! What should we do <CHARNAME>? How can Boo be safely returned to us?~
++ ~It is for Billy to tell us the truth of Boo's disappearance. Nobody else can help us.~ EXTERN WWBILL Cantmakeme
++ ~I think Billy should damn well tell us where Boo is!~ EXTERN WWBILL Cantmakeme
END

IF ~~ iwillfight
SAY ~<CHARNAME> might not be ready, but Minsc is!! Let us fight NOW!~
IF ~~ THEN DO ~   SetGlobal("FightVivick","GLOBAL",1) 
			SetGlobal("FightVivickNow","GLOBAL",1)~ EXIT      // ie delay too long and Minsc will fight provided he is healthy
END

IF ~~ MinscExplain
SAY ~Oh, it is a sad and tragic story to rival the greatest and most unfortunate tales of all time! A hero and his hamster are parted! Minsc and Boo, taken from each other by this evil little boy! Where is justice? Is it not right that Minsc should buttkick this boy?~
IF ~~ THEN EXTERN WWVIVI Laughs
END

IF ~~ BetrayalBoo
SAY ~There is something strange in your eye, <CHARNAME>... I think I will ask Boo what he thinks. Litt- er, big grey hamster, are you who <CHARNAME> says you are?~
IF ~~ THEN GOTO LiarCharname
END

IF ~~ TravelRoad
SAY ~But- but Boo never runs on the road! He has sensitive feet! I am thinking this is not Boo! Litt- er, big grey hamster, are you who <CHARNAME> says you are?~
IF ~~ THEN GOTO LiarCharname
END


IF ~~ SoBig
SAY ~But he seems so big. Boo was never so big...~
++ ~Smethy probably feeds him more than you do. Plus he hasn't had the exercise of combat.~ + NoCombat
++ ~Well, Boo *is* a giant space hamster. He's meant to be big, right?~ + MeantToBe
END

IF ~~ MeantToBe
SAY ~NO! Boo is a MINIATURE giant space hamster!! I think- I think you have been lying to Minsc! Litt- er, big grey hamster! Is it true when <CHARNAME> says you are Boo?~
IF ~~ THEN GOTO LiarCharname
END

IF ~~ LiarCharname
SAY ~I see. So you say you are not Boo? And yet <CHARNAME> insists it is so! That would mean-~
= ~That would mean that <CHARNAME> is a... a liar...~
= ~What- what is this boiling in Minsc's blood? Why is Minsc seeing red suddenly? It is because <CHARNAME> is made of stinking evil!! <PRO_HESHE> has lied to Minsc and betrayed him too!~
= ~And poor- poor Boo is still lost... he will think that Minsc has abandoned him! Ohh Boo, I will not blame you if you have become an evil pirate or a drunken sailor while Minsc was gone...~
= ~I will go find Boo RIGHT NOW! He may be swinging a tiny cutlass or singing a sea shanty as we speak! Ohh, Minsc has failed you so...~
= ~<CHARNAME>! This is not the end! I will find Boo and we will chop you into evil sized pieces and Boo will stomp his pegleg in your remains!~
IF ~~ THEN SOLVED_JOURNAL ~An elf, the ranger, a Minsc and his hamster.

Minsc has discovered that pseudo-Boo is not in fact Boo. The outraged ranger has left my group and worse, has taken the cleric elf Aerie with him. My party will be the weaker for their loss and I would do well to refrain from such practical jokes in future.~
				DO ~LeaveParty()
			   SG("WWBooGone",4)
   			   GivePartyAllEquipment()
			   MoveToPoint(\[177.395\]))
			   EscapeAreaDestroy(2)
			   SetGlobal("WWBetrayedMinsc","GLOBAL",1)
			   SG("WWSmethyChastens",1)~ EXIT


END

END   // APPENDING MINSCJ

/* Jaheira */

APPEND ~JAHEIRAJ~

IF ~~ IdiotCharname
SAY ~Idiot! Attacking him will do us no good! Can you not see that there is no exit for us unless we cooperate? Honestly, you are that much of a fool, sometimes!~
IF ~~ THEN EXTERN WWSWOO niceMan
END

END   // APPENDING JAHEIRAJ

/* Edwin */
APPEND ~EDWINJ~

IF ~~ EdwinCommentAerie
SAY ~So the great oaf has finally left. As an added bonus, that little waif has gone with him! I must hand it to you, <CHARNAME>, for eliminating two birds with one rat.~
IF ~~ THEN SOLVED_JOURNAL ~An elf, the ranger, a Minsc and his hamster.

Minsc has discovered that pseudo-Boo is not in fact Boo. The outraged ranger has left my group and worse, has taken the cleric elf Aerie with him. My party will be the weaker for their loss and I would do well to refrain from such practical jokes in future.~ EXIT
END

IF ~~ EdwinComment
SAY ~So the great oaf has finally left. Perhaps before long, he'll join his ex-witch in fertilising the soil. One can only hope.~
IF ~~ THEN SOLVED_JOURNAL ~A Boo, the ranger, a Minsc and his hamster.

Minsc has discovered that pseudo-Boo is not in fact Boo. The outraged ranger has left my group to find his hamster and I doubt we will be able to find favour with him again. My party will be the weaker for their loss and I would do well to refrain from such practical jokes in future.~ EXIT
END

IF ~~ EdwinYawn
SAY ~Child's play. O fearless leader, do you require Edwin's help? (Ugh, I can almost hear the rusty cogs echo in <PRO_HISHER> thick skull as they try to turn.)~
IF ~~ THEN EXTERN EDWINJ EdwinHelp
END

IF ~~ EdwinHelp
SAY ~Well? (Patience, patience, <CHARNAME> is likely making room for a new thought in <PRO_HISHER> goodberry of a brain.)~
++ ~Tell me the answer, Edwin.~ + TellAnswer
++ ~The answer is a horse.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong1
++ ~A wheel.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong1
++ ~A driver.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE Wrong1
++ ~Noise.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE Right1
++ ~Seats.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong1
++ ~Passengers.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong1
++ ~A mephit named Noober.~ EXTERN WWELLE TotallyWrong
++ ~You, Lady De'Lyl.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE YouLady
END

IF ~~ THEN AskEdwin
SAY ~Oh do not strain your brain thinking up a coherent answer to my question. A grunt will suffice. (Who would have thought that I would become so fluent in monkey language? Mother will be so.. disappointed.)~
++ ~Grunt.~ + AnswerEdwin2
++ ~Edwin, just tell me the answer.~ + AnswerEdwin2
++ ~A walking stick.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong2
++ ~A cabbage.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE  Right2
++ ~A key.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong2
++ ~A heron.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong2
++ ~A lover.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong2
++ ~A one-legged lover.. a pirate lover?~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE Wrong2
++ ~A spider missing 7 legs as well as having been born with a defective heart.~ EXTERN WWELLE TotallyWrong
+ ~Gender(Player1,MALE)~ + ~Me when I gaze upon your beauty.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE YouBeauty
+ ~Gender(Player1,FEMALE)~ + ~Any man, should he chance to come across your beauty.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE YouBeauty
END

IF ~~ AnswerEdwin2
SAY ~It is a cabbage. (Yes, the one that your brain so amusingly resembles.)~
++ ~A cabbage.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE  Right2
++ ~A walking stick.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong2
++ ~A key.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong2
++ ~A heron.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE  Wrong2
++ ~A fireplace.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong2
++ ~A lover.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",0)~ EXTERN WWELLE Wrong2
++ ~A one-legged lover.. a pirate lover?~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",1)~ EXTERN WWELLE Wrong2
++ ~A spider missing 7 legs as well as having been born with a defective heart.~ EXTERN WWELLE TotallyWrong
+ ~Gender(Player1,MALE)~ + ~Me when I gaze upon your beauty.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE YouBeauty
+ ~Gender(Player1,FEMALE)~ + ~Any man, should he chance to come across your beauty.~ DO ~IncrementGlobal("WWEllyQuestions","GLOBAL",2)~ EXTERN WWELLE YouBeauty
END

IF ~~ NotSimpleEnough
SAY ~(But not simple enough, it appears.) <CHARNAME>, I suppose you require my help once again? (What next, tying <PRO_HISHER> belt-buckles in the morning?)~
IF ~~ THEN EXTERN EDWINJ AskEdwin
END

END


/* Aerie */

APPEND ~AERIEJ~

IF ~~ AerieJoins
SAY ~Oh! (sob!) I can't believe you'd do such.. such a horrible thing, <CHARNAME>! To take something so precious from Minsc! I... I won't be a part of this!~
IF ~~ THEN SOLVED_JOURNAL ~An elf, the ranger, a Minsc and his hamster.

Minsc has discovered that pseudo-Boo is not in fact Boo. The outraged ranger turned on me and I was forced to slay him. To add to my troubles, the cleric-mage Aerie has left my party as a result. My party will be the weaker for their loss and I would do well to refrain from such practical jokes in future.~
				DO ~SetGlobal("AerieRomanceActive","GLOBAL",3)
				SG("WWBooGone",5)
				LeaveParty()
				GivePartyAllEquipment()
				EscapeArea()
				ActionOverride("Minsc",EquipMostDamagingMelee())
				ActionOverride("Minsc",LeaveParty())
				ActionOverride("Minsc",Enemy())
				ActionOverride("Minsc",Attack(Player1))~ EXIT
END

IF ~~ MinscRomance
SAY ~Oh! Poor, poor Minsc! H- how could you do this to him, <CHARNAME>?~
++ ~I thought it would be funny. And it WAS. Say, do you have any pets?~ + NastyReply
++ ~I'm sorry Aerie, my little joke went horribly wrong. I doubt he will forgive us, but I sincerely hope he finds his hamster.~ + SincereReply
+ ~CheckStatGT(Player1,14,CHR)~ + ~It was just a joke, meant to make you smile. You're so beautiful when you smile, Aerie.~ + JokeHigh
+ ~OR(2)
	CheckStat(Player1,14,CHR)
	CheckStatLT(Player1,14,CHR)~ + ~It was just a joke, meant to make you smile. You're so beautiful when you smile, Aerie.~ + JokeLow
END

IF ~~ NastyReply
SAY ~Y-you're still joking? At a time like this? Minsc lost... he lost something so precious to him... and y-you smile at it! I- I thought better of you, <CHARNAME>. I.. I was wrong.~
IF ~~ THEN DO ~SetGlobal("AerieRomanceActive","GLOBAL",3)~ EXIT
END

IF ~~ SincereReply
SAY ~I.. I believe you, <CHARNAME>. B- but to lose... to lose something so precious... Oh! I don't want to think about it anymore!~
IF ~~ THEN EXIT
END

IF ~~ JokeHigh
SAY ~Oh! What a horrible joke to play! B-but it was a mistake... and you won't do anything... anything so awful again, will you? I- I'd prefer to smile at less horrible jokes, <CHARNAME>.~
IF ~~ THEN EXIT
END

IF ~~ JokeLow
SAY ~Y-you wanted to make m-me smile? By hurting Minsc? I thought better of you, <CHARNAME>... I was wrong. I... I'd like to be left alone now.~
IF ~~ THEN DO ~SetGlobal("AerieRomanceActive","GLOBAL",3)~ EXIT
END

END



// Minsc's kicked out & unhappiness dialogues

APPEND ~MINSCP~

IF WEIGHT #-5 ~G("WWBooGone",1)
			   Global("WWLeave","LOCALS",0)~ THEN MinscLeavesForever
SAY ~You want Minsc to leave? But we have not found Boo yet!~
++ ~Sorry, Minsc. Go wait at the Copper Coronet. We will meet you there if we need your services again.~ + ByeService
++ ~Wait right here.  We'll come back later if we need your help.~ + ByeService
++ ~I could not leave you all alone in this place. Join with me once again, Minsc.~ + JoinAgain
END

IF ~~ ByeService
SAY ~I do not understand. You wish Minsc to help you later, yet now you do not help Minsc? If Boo were here, he would undoubtably make this make sense, but as he is NOT here, Minsc will just revise his opinion of <CHARNAME> to include the words 'stinking' and 'evil'.~
= ~I will go to find Boo by MYSELF! Boo would not appreciate being rescued by so selfish a <CHARNAME>!~
IF ~~ THEN SOLVED_JOURNAL ~Where oh where has my little Boo gone?

Minsc has left my party in anger after I told him that we must part. The ranger did not understand how I could leave him while his hamster was still missing and has stormed off, vowing to look for Boo. I do not think we will see his like again.~
		DO ~SetGlobal("WWLeave","LOCALS",1)
		SG("WWBooGone",5)
		GivePartyAllEquipment()
		EraseJournalEntry(@2)
		EraseJournalEntry(@3)
		EscapeArea()~ EXIT
END

IF ~~ JoinAgain
SAY ~You almost had Minsc sweating for a moment, <CHARNAME>. Let us keep on searching for Boo, eh?~
IF ~~ THEN DO ~JoinParty()~ EXIT
END

END


///////////////////////
/* Random interjects */
///////////////////////

INTERJECT_COPY_TRANS BMINSC 14 MinscAddedComment
  == MINSCJ   IF ~OR(2)  Global("WWBooGone","GLOBAL",2)
						 Global("WWBooGone","GLOBAL",3)~ THEN
    ~Boo has been missing once already, and that caused great grief to Minsc!~
END

INTERJECT_COPY_TRANS DBEGGAR 0 MinscBeggar
  == MINSCJ IF ~Global("WWBooGone","GLOBAL",1)~ THEN
	~No, YOU! You owe me an answer! Have you seen my hamster? About yea big?~
  == DBEGGAR IF ~Global("WWBooGone","GLOBAL",1)~ THEN
	~Ehm- no? Have you got the money you owe me, by any chance?~
END


