REPLACE_STATE_TRIGGER ARKION 6 ~Global("HelpArkion","GLOBAL",1)~

REPLACE ARKION
IF ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("MISC80")~ THEN BEGIN 3
  SAY @0 /* #15015 */
  IF ~~ THEN DO ~SetGlobal("HelpArkion","GLOBAL",1) TakePartyItem("MISC80") GivePartyGold(250) AddexperienceParty(1800)~ EXIT
END
END

APPEND ARKION
IF WEIGHT #0 ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("MISC79")~ THEN BEGIN EitherBody
  SAY @0 /* #15015 */
  IF ~~ THEN DO ~SetGlobal("HelpArkion","GLOBAL",1) TakePartyItem("MISC79") GivePartyGold(250) AddexperienceParty(1800)~ EXIT
END

IF WEIGHT #0 ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("UBFEBODY")~ THEN BEGIN NobleBody
  SAY @16
  IF ~~ THEN EXIT
END
END

REPLACE SCAR
IF ~~ THEN BEGIN 34
  SAY @1
  IF ~PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("RING19")~ REPLY @2 GOTO AlreadyHaveBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("RING19")~ REPLY @3 GOTO NoWay
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("RING19")~ REPLY @4 GOTO WillReturnBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("RING19")~ REPLY @5 GOTO NoWay
END
END

APPEND SCAR
IF ~~ THEN BEGIN AlreadyHaveBody
  SAY @6
  IF ~~ THEN DO ~TakePartyItem("UBFEBODY")
GiveGoldForce(3000)
AddexperienceParty(3000)
SetGlobal("ScarMission","GLOBAL",5)
SetGlobal("ScarBodyFetch","GLOBAL",3)
EscapeArea()~ JOURNAL #10649 /* ~Scar is waiting outside of the Flaming Fist barracks.  He wants to discuss the suspicions he has about the Iron Throne.~ */ EXIT
END

IF ~~ THEN BEGIN NoWay
  SAY @7
  IF ~~ THEN DO ~GiveGoldForce(500)
AddexperienceParty(3000)
SetGlobal("ScarMission","GLOBAL",5)
SetGlobal("ScarBodyFetch","GLOBAL",2)
EscapeArea()
~ JOURNAL #10649 /* ~Scar is waiting outside of the Flaming Fist barracks.  He wants to discuss the suspicions he has about the Iron Throne.~ */ EXIT
END

IF ~~ THEN BEGIN WillReturnBody
  SAY @8
  IF ~~ THEN DO ~SetGlobal("ScarBodyFetch","GLOBAL",1)~ EXIT
END

IF WEIGHT #0 ~Global("ScarBodyFetch","GLOBAL",1)~ THEN BEGIN BodyFetchQuestReturn
  SAY @9
  IF ~PartyHasItem("UBFEBODY")~ THEN REPLY @10 GOTO AlreadyHaveBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN REPLY @11 GOTO NoBodyYet
  IF ~~ THEN REPLY @12 GOTO NoWay
END

IF WEIGHT #0 ~Global("ScarBodyFetch","GLOBAL",2)
PartyHasItem("UBFEBODY")~ THEN BEGIN ChangedMind
  SAY @13
  IF ~~ THEN REPLY @14 GOTO AlreadyHaveBody
END

IF ~~ THEN BEGIN NoBodyYet
  SAY @15
  IF ~~ THEN EXIT
END
END