REPLACE_STATE_TRIGGER %tutu_var%ARKION 6 ~Global("HelpArkion","GLOBAL",1)~

REPLACE %tutu_var%ARKION
IF ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("%tutu_var%MISC80")~ THEN BEGIN 3
  SAY @0
  IF ~PartyHasItem("%tutu_var%MISC80")~ THEN DO ~SetGlobal("HelpArkion","GLOBAL",1) TakePartyItem("%tutu_var%MISC80") GivePartyGold(250) AddexperienceParty(1800)~ EXIT
END
END

APPEND %tutu_var%ARKION
IF WEIGHT #0 ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("%tutu_var%MISC79")~ THEN BEGIN EitherBody
  SAY @0
  IF ~PartyHasItem("%tutu_var%MISC79")~ THEN DO ~SetGlobal("HelpArkion","GLOBAL",1) TakePartyItem("%tutu_var%MISC79") GivePartyGold(250) AddexperienceParty(1800)~ EXIT
END

IF WEIGHT #0 ~Global("HelpArkion","GLOBAL",0)
PartyHasItem("UBFEBODY")~ THEN BEGIN NobleBody
  SAY @16
  IF ~~ THEN EXIT
END
END

REPLACE %tutu_var%SCAR
IF ~~ THEN BEGIN 34
  SAY @1
  IF ~PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("%tutu_var%RING19")~ REPLY @2 GOTO AlreadyHaveBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("%tutu_var%RING19")~ REPLY @3 GOTO NoWay
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("%tutu_var%RING19")~ REPLY @4 GOTO WillReturnBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN DO ~TakePartyItem("%tutu_var%RING19")~ REPLY @5 GOTO NoWay
END
END

APPEND %tutu_var%SCAR
IF ~~ THEN BEGIN AlreadyHaveBody
  SAY @6
  IF ~~ THEN DO ~TakePartyItem("UBFEBODY")
GiveGoldForce(3000)
AddexperienceParty(3000)
SetGlobal("ScarMission","GLOBAL",5)
SetGlobal("ScarBodyFetch","GLOBAL",3)
EscapeArea()~ JOURNAL @20008 EXIT
END

IF ~~ THEN BEGIN NoWay
  SAY @7
  IF ~~ THEN DO ~GiveGoldForce(500)
AddexperienceParty(3000)
SetGlobal("ScarMission","GLOBAL",5)
SetGlobal("ScarBodyFetch","GLOBAL",2)
EscapeArea()~ JOURNAL @20008 EXIT
END

IF ~~ THEN BEGIN WillReturnBody
  SAY @8
  IF ~~ THEN DO ~SetGlobal("ScarBodyFetch","GLOBAL",1)~ EXIT
END

IF WEIGHT #0 ~Global("ScarBodyFetch","GLOBAL",1)~ THEN BEGIN BodyFetchQuestReturn
  SAY @9
  IF ~PartyHasItem("UBFEBODY")~ THEN REPLY @10 GOTO AlreadyHaveBody
  IF ~!PartyHasItem("UBFEBODY")~ THEN REPLY @11 GOTO NoBodyYet
  IF ~~ THEN REPLY @12 GOTO NoWay
END

IF WEIGHT #0 ~Global("ScarBodyFetch","GLOBAL",2)
PartyHasItem("UBFEBODY")~ THEN BEGIN ChangedMind
  SAY @13
  IF ~~ THEN REPLY @14 GOTO AlreadyHaveBody
END

IF ~~ THEN BEGIN NoBodyYet
  SAY @15
  IF ~~ THEN EXIT
END
END